UDF > GUI > GuiEdit >

_GUICtrlEdit_SetReadOnly

Active ou désactive le style lecture seule ($ES_READONLY)

#include <GuiEdit.au3>
_GUICtrlEdit_SetReadOnly ( $hWnd, $bReadOnly )

Paramètres

$hWnd ID/handle du contrôle
$bReadOnly Valeurs suivantes:
    True - Active le style $ES_READONLY
    False - Désactive le style $ES_READONLY

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <GuiStatusBar.au3>

Example()

Func Example()
    Local $hStatusBar, $idEdit, $hGUI
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"
    Local $aPartRightSide[4] = [120, 248, 378, -1]

    ; Crée une GUI
    $hGUI = GUICreate("Edit Set Read Only", 400, 300)
    $idEdit = GUICtrlCreateEdit("", 2, 2, 394, 268)
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
    _GUICtrlStatusBar_SetIcon($hStatusBar, 3, 97, "shell32.dll")
    GUISetState(@SW_SHOW)

    ; Définit les marges
    _GUICtrlEdit_SetMargins($idEdit, BitOR($EC_LEFTMARGIN, $EC_RIGHTMARGIN), 10, 10)

    ; Ajoute du texte
    _GUICtrlEdit_SetText($idEdit, FileRead($sFile))
    _GUICtrlEdit_LineScroll($idEdit, 0, _GUICtrlEdit_GetLineCount($idEdit) * -1)

    ; Obtient le Flag  modifié
    _GUICtrlStatusBar_SetText($hStatusBar, "Modified: " & _GUICtrlEdit_GetModify($idEdit), 2)

    ; Installe Read Only
    _GUICtrlEdit_SetReadOnly($idEdit, True)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example