UDF > GUI > GuiEdit >

_GUICtrlEdit_GetModify

Obtient l'état de l'indicateur de modification d'un contrôle d'édition

#include <GuiEdit.au3>
_GUICtrlEdit_GetModify ( $hWnd )

Paramètre

$hWnd ID/handle de contrôle

Valeur de retour

Retourne True: Le contenu du contrôle d'édition a été modifié.
Retourne False: Le contenu du contrôle d'édition n'a pas été modifié.

Remarque

Le système met automatiquement l'indicateur de modification à zéro lorsque le contrôle est créé.
Si l'utilisateur modifie le texte du contrôle, le système définit l'indicateur à True.
Vous pouvez appeler _GUICtrlEdit_SetModify() pour définir ou effacer l'indicateur.

En relation

_GUICtrlEdit_CanUndo, _GUICtrlEdit_SetModify, _GUICtrlEdit_Undo

Exemple

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <GuiStatusBar.au3>

Example()

Func Example()
    Local $hStatusBar, $idEdit, $hGUI
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"
    Local $aPartRightSide[4] = [120, 248, 378, -1]

    ; Crée une GUI
    $hGUI = GUICreate("Edit Get Modify", 400, 300)
    $idEdit = GUICtrlCreateEdit("", 2, 2, 394, 268)
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
    _GUICtrlStatusBar_SetIcon($hStatusBar, 3, 97, "shell32.dll")
    GUISetState(@SW_SHOW)

    ; Définit les marges
    _GUICtrlEdit_SetMargins($idEdit, BitOR($EC_LEFTMARGIN, $EC_RIGHTMARGIN), 10, 10)

    ; Ajoute le texte
    _GUICtrlEdit_AppendText($idEdit, FileRead($sFile))
    _GUICtrlEdit_LineScroll($idEdit, 0, _GUICtrlEdit_GetLineCount($idEdit) * -1)

    ; Obtient le flag modifié
    _GUICtrlStatusBar_SetText($hStatusBar, "Modified: " & _GUICtrlEdit_GetModify($idEdit), 2)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example