UDF > GUI > GuiStatusBar >


_GUICtrlStatusBar_SetIcon

Définit l'icône associée à une partie

#include <GuiStatusBar.au3>
_GUICtrlStatusBar_SetIcon ( $hWnd, $iPart [, $hIcon = -1 [, $sIconFile = ""]] )

Paramètres

$hWnd Handle du contrôle StatusBar
$iPart Index de base 0, de la partie. Si le contrôle est en mode simple, ce champ est ignoré.
$hIcon [optionnel] Handle de l'icône. Si cette valeur est -1, l'icône est supprimée.
$sIconFile [optionnel] Nom du fichier icône à utiliser.

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUICtrlStatusBar_GetIcon

Exemples

Exemple 1

#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WinAPIIcons.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hStatus
    Local $aParts[4] = [75, 150, 300, -1]

    ; Crée une GUI
    $hGUI = GUICreate("(Example 1) StatusBar Set Icon", 400, 300)
    $hStatus = _GUICtrlStatusBar_Create($hGUI)

    ; Crée un contrôle memo
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Définit des parties
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)
    _GUICtrlStatusBar_SetText($hStatus, "Part 1")
    _GUICtrlStatusBar_SetText($hStatus, "Part 2", 1)
    _GUICtrlStatusBar_SetText($hStatus, "Part 3", 2)
    _GUICtrlStatusBar_SetText($hStatus, "Part 4", 3)

    ; Définit des icônes
    $ahIcons[0] = _WinAPI_LoadShell32Icon(23)
    $ahIcons[1] = _WinAPI_LoadShell32Icon(40)
    _GUICtrlStatusBar_SetIcon($hStatus, 0, $ahIcons[0])
    _GUICtrlStatusBar_SetIcon($hStatus, 1, $ahIcons[1])

    ; Affiche les handles des icônes
    MemoWrite("Part 1 icon handle .: 0x" & Hex(_GUICtrlStatusBar_GetIcon($hStatus, 0)))
    MemoWrite("Part 2 icon handle .: 0x" & Hex(_GUICtrlStatusBar_GetIcon($hStatus, 1)))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    ; Libère les icônes
    _WinAPI_DestroyIcon($ahIcons[0])
    _WinAPI_DestroyIcon($ahIcons[1])
    
    GUIDelete()
EndFunc   ;==>Example

; Ecrit un message dans le contrôle memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite


Exemple 2

#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hStatus
    Local $aParts[4] = [75, 150, 300, 400]

    ; Crée une GUI
    $hGUI = GUICreate("(Example 2) StatusBar Set Icon", 400, 300)
    $hStatus = _GUICtrlStatusBar_Create($hGUI)

    ; Crée un contrôle memo
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Définit des parties
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)
    _GUICtrlStatusBar_SetText($hStatus, "Part 1")
    _GUICtrlStatusBar_SetText($hStatus, "Part 2", 1)
    _GUICtrlStatusBar_SetText($hStatus, "Part 3", 2)
    _GUICtrlStatusBar_SetText($hStatus, "Part 4", 3)

    ; Définit des icônes
    _GUICtrlStatusBar_SetIcon($hStatus, 0, 23, "shell32.dll")
    _GUICtrlStatusBar_SetIcon($hStatus, 1, 40, "shell32.dll")

    ; Affiche les handles des icônes
    MemoWrite("Part 1 icon handle .: 0x" & Hex(_GUICtrlStatusBar_GetIcon($hStatus, 0)))
    MemoWrite("Part 2 icon handle .: 0x" & Hex(_GUICtrlStatusBar_GetIcon($hStatus, 1)))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Ecrit un message dans le contrôle memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite