UDF > GUI > GuiEdit >

_GUICtrlEdit_GetLineCount

Obtient le nombre de lignes du texte d'un contrôle d'édition

#include <GuiEdit.au3>
_GUICtrlEdit_GetLineCount ( $hWnd )

Paramètre

$hWnd ID/handle du contrôle

Valeur de retour

Succès: Retourne le nombre total de lignes de texte.
Échec: Retourne 1.

Remarques

Si le contrôle n'a pas de texte, la valeur de retour est 1.
La valeur de retour ne sera jamais inférieure à 1.

La fonction _GUICtrlEdit_GetLineCount() récupère le nombre total de lignes de texte, et pas seulement le nombre de lignes qui sont actuellement visibles.

Si l'option Wordwrap est activée, le nombre de lignes peut changer lorsque les dimensions de la fenêtre d'édition changent.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <GuiStatusBar.au3>

Example()

Func Example()
    Local $hStatusBar, $idEdit, $hGUI
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"

    ; Crée une GUI
    $hGUI = GUICreate("Edit Get Line Count", 400, 300)
    $idEdit = GUICtrlCreateEdit("", 2, 2, 394, 268)
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI, -1)
    GUISetState(@SW_SHOW)

    _GUICtrlEdit_SetText($idEdit, FileRead($sFile))
    _GUICtrlStatusBar_SetIcon($hStatusBar, 0, 97, "shell32.dll")
    _GUICtrlStatusBar_SetText($hStatusBar, @TAB & "Lines: " & _GUICtrlEdit_GetLineCount($idEdit))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example