UDF > GUI > GuiStatusBar >


_GUICtrlStatusBar_SetText

Définit le texte d'une partie d'un contrôle StatusBar

#include <GuiStatusBar.au3>
_GUICtrlStatusBar_SetText ( $hWnd [, $sText = "" [, $iPart = 0 [, $iUFlag = 0]]] )

Paramètres

$hWnd Handle du contrôle StatusBar
$sText [optionnel] Le texte à afficher dans la partie
$iPart [optionnel] La partie qui doit contenir le texte
$iUFlag [optionnel] Type d'opération de dessin. Le type peut prendre l'une des valeurs suivantes:
    0 - Le texte est dessiné avec une bordure qui apparaît plus bas que le niveau de la fenêtre
    $SBT_NOBORDERS - Le texte est dessiné sans bordure
    $SBT_OWNERDRAW - Le texte est dessiné par la fenêtre parent
    $SBT_POPOUT - Le texte est dessiné avec une bordure qui apparaît plus haut que le niveau de la fenêtre
    $SBT_RTLREADING - Le texte est affiché dans la direction opposée du texte de la fenêtre parent

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarque

Définissez $iPart à $SB_SIMPLEID pour un StatusBar simple.

En relation

_GUICtrlStatusBar_GetText

Exemples

Exemple 1

#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WinAPIIcons.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $ahIcons[2], $hStatus
    Local $aParts[4] = [75, 150, 300, 400]

    ; Crée une GUI
    $hGUI = GUICreate("(Example 1) StatusBar Set Text", 400, 300)
    $hStatus = _GUICtrlStatusBar_Create($hGUI)

    ; Crée un contrôle memo
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Définit des parties
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)
    _GUICtrlStatusBar_SetText($hStatus, "Part 1")
    _GUICtrlStatusBar_SetText($hStatus, "Part 2", 1)
    _GUICtrlStatusBar_SetText($hStatus, "Part 3", 2)
    _GUICtrlStatusBar_SetText($hStatus, "Part 4", 3)
    Local $iWrongSetText = _GUICtrlStatusBar_SetText($hStatus, "Wrong Part", 4)

    ; Définit des icônes
    $ahIcons[0] = _WinAPI_LoadShell32Icon(23)
    $ahIcons[1] = _WinAPI_LoadShell32Icon(40)
    _GUICtrlStatusBar_SetIcon($hStatus, 0, $ahIcons[0])
    _GUICtrlStatusBar_SetIcon($hStatus, 1, $ahIcons[1])

    ; Affiche le texte des parties
    MemoWrite("Part 1 text ........: " & _GUICtrlStatusBar_GetText($hStatus, 0))
    MemoWrite("Part 2 text ........: " & _GUICtrlStatusBar_GetText($hStatus, 1))

    ; Affiche le handle des icônes
    MemoWrite("Part 1 icon handle .: 0x" & Hex(_GUICtrlStatusBar_GetIcon($hStatus, 0)))
    MemoWrite("Part 2 icon handle .: 0x" & Hex(_GUICtrlStatusBar_GetIcon($hStatus, 1)))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Libère les icônes
    _WinAPI_DestroyIcon($ahIcons[0])
    _WinAPI_DestroyIcon($ahIcons[1])
    GUIDelete()
EndFunc   ;==>Example

; Ecrit un message dans le contrôle memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite


Exemple 2

#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hStatus
    Local $aParts[4] = [75, 150, 300, 400]

    ; Crée une GUI
    $hGUI = GUICreate("(Example 2) StatusBar Set Text", 400, 300)
    $hStatus = _GUICtrlStatusBar_Create($hGUI)

    ; Crée un contrôle memo
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Définit des parties
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)
    _GUICtrlStatusBar_SetText($hStatus, "Part 1")
    _GUICtrlStatusBar_SetText($hStatus, "Part 2", 1)
    _GUICtrlStatusBar_SetText($hStatus, "Part 3", 2)
    _GUICtrlStatusBar_SetText($hStatus, "Part 4", 3)

    ; Définit des icônes
    _GUICtrlStatusBar_SetIcon($hStatus, 0, 23, "shell32.dll")
    _GUICtrlStatusBar_SetIcon($hStatus, 1, 40, "shell32.dll")

    ; Affiche le texte des parties
    MemoWrite("Part 1 text ........: " & _GUICtrlStatusBar_GetText($hStatus, 0))
    MemoWrite("Part 2 text ........: " & _GUICtrlStatusBar_GetText($hStatus, 1))

    ; Affiche le handle des icônes
    MemoWrite("Part 1 icon handle .: 0x" & Hex(_GUICtrlStatusBar_GetIcon($hStatus, 0)))
    MemoWrite("Part 2 icon handle .: 0x" & Hex(_GUICtrlStatusBar_GetIcon($hStatus, 1)))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Ecrit un message dans le contrôle memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite