UDF > GUI > GuiEdit >


_GUICtrlEdit_SetMargins

Définit les largeurs des marges gauche et droite

#include <GuiEdit.au3>
_GUICtrlEdit_SetMargins ( $hWnd [, $iMargin = 0x1 [, $iLeft = 0xFFFF [, $iRight = 0xFFFF]]] )

Paramètres

$hWnd ID/handle du contrôle
$iMargin [optionnel] Peut prendre une ou plusieurs des valeurs suivantes:
    $EC_LEFTMARGIN - Définit la marge gauche
    $EC_RIGHTMARGIN - Définit la marge droite

Default: $EC_LEFTMARGIN
$iLeft [optionnel] La nouvelle largeur de la marge gauche

Default: $EC_USEFONTINFO
$iRight [optionnel] La nouvelle largeur de la marge droite

Default: $EC_USEFONTINFO

Valeur de retour

Retourne un tableau dans le format suivant:
    [0] - La largeur de la marge gauche
    [1] - La largeur de la marge droite

En relation

_GUICtrlEdit_GetMargins

Exemple

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hStatusBar, $idEdit, $hGUI
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"
    Local $aPartRightSide[3] = [190, 378, -1], $aMargins

    ; Crée une GUI
    $hGUI = GUICreate("Edit Set Margins", 400, 300)
    $idEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
    _GUICtrlStatusBar_SetIcon($hStatusBar, 2, 97, "shell32.dll")
    GUISetState(@SW_SHOW)

    ; Définit les marges
    _GUICtrlEdit_SetMargins($idEdit, BitOR($EC_LEFTMARGIN, $EC_RIGHTMARGIN), 10, 10)

    ; Définit le texte
    _GUICtrlEdit_SetText($idEdit, FileRead($sFile))

    ; Obtient les marges
    $aMargins = _GUICtrlEdit_GetMargins($idEdit)
    _GUICtrlStatusBar_SetText($hStatusBar, "Left Margin: " & $aMargins[0])
    _GUICtrlStatusBar_SetText($hStatusBar, "Right Margin: " & $aMargins[1], 1)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example