Functions > GUI > GUICtrlCreate >

GUICtrlCreateEdit

Crée un contrôle Edit pour une GUI.

GUICtrlCreateEdit ( "text", left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )

Paramètres

text	Le texte du contrôle.
left	Coordonnée X du coin supérieur gauche du contrôle. Si vous utilisez -1, X sera calculée en accord avec GUICoordMode.
top	Coordonnée Y du coin supérieur gauche du contrôle. Si vous utilisez -1, Y sera calculée en accord avec GUICoordMode.
width	[optionnel] Largeur du contrôle (par défaut, la largeur utilisée précédemment).
height	[optionnel] Hauteur du contrôle (par défaut, la hauteur utilisée précédemment).
style	[optional] Définit les styles du contrôle. Consultez l'Annexe des styles d'un contrôle GUI. Par défaut (-1) : $ES_WANTRETURN, $WS_VSCROLL, $WS_HSCROLL, $ES_AUTOVSCROLL, $ES_AUTOHSCROLL Styles forcés : $ES_MULTILINE, $WS_TABSTOP seulement sans $ES_READONLY
exStyle	[optionnel] Définit les styles étendus du contrôle. Consultez la Table des styles étendus. Par défaut (-1) : $WS_EX_CLIENTEDGE

Valeur de retour

Succès:	Retourne l'ID du nouveau contrôle.
Échec:	Retourne 0.

Remarques

Pour obtenir la valeur du contrôle, consultez GUICtrlRead.
Pour définir ou modifier des informations dans le contrôle, consultez GUICtrlUpdate....

Pour combiner des styles avec le style par défaut, utilisez BitOR($GUI_SS_DEFAULT_EDIT, newstyle,...).
Pour utiliser les valeurs indiquées ci-dessus, vous devez inclure <EditConstants.au3> dans votre script.

Si vous souhaitez glisser et déposer (drag & drop) un nom de fichier sur ce contrôle, il suffit d'ajouter le style étendu WS_EX_ACCEPTFILES dans GUICreate() et définir l'état à $GUI_DROPACCEPTED.
Si plusieurs fichiers sont sélectionnés, ils seront déposés sur des lignes distinctes.

Le redimensionnement par défaut est $GUI_DOCKAUTO, la taille et la position seront modifiés.

La création d'un contrôle RichEdit est trop complexe donc ne sera pas inclus dans un contrôle de base.
Vous devez utiliser _GUICtrlRichEdit_Create().

En relation

GUICoordMode (Option), GUICtrlRead, GUICtrlSetData, GUICtrlSetLimit, GUICtrlSetState, GUIGetMsg

Exemple

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    GUICreate("My GUI edit") ; Crée une GUI centrée sur l'écran

    Local $idMyedit = GUICtrlCreateEdit("First line" & @CRLF, 176, 32, 121, 97, $ES_AUTOVSCROLL + $WS_VSCROLL)

    GUISetState(@SW_SHOW)

    Send("{END}")

    ; Données ajoutées: n'oubliez pas le 3ème paramètre
    GUICtrlSetData($idMyedit, "Second line", 1)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example