UDF > GUI > GuiEdit >


_GUICtrlEdit_LineScroll

Fait défiler le texte

#include <GuiEdit.au3>
_GUICtrlEdit_LineScroll ( $hWnd, $iHoriz, $iVert )

Paramètres

$hWnd ID/handle du contrôle
$iHoriz Spécifie le nombre de caractères pour le défilement horizontal.
$iVert Spécifie le nombre de lignes pour le défilement vertical.

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarques

Le contrôle ne défile pas verticalement passée la dernière ligne de texte.

Si la ligne courante plus le nombre de lignes spécifié par le paramètre $iVert dépasse le nombre total de lignes du contrôle d'édition, la valeur est ajustée de sorte que la dernière ligne défile jusqu'en haut de la fenêtre du contrôle d'édition.

_GUICtrlEdit_LineScroll() fait défiler le texte verticalement ou horizontalement.
_GUICtrlEdit_LineScroll() peut être utilisée pour faire défiler horizontalement passé le dernier caractère d'une ligne.

En relation

_GUICtrlEdit_Scroll

Exemple

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hStatusBar, $idEdit, $hGUI, $sText

    ; Crée une GUI
    $hGUI = GUICreate("Edit Line Scroll", 400, 300)
    $idEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI)
    GUISetState(@SW_SHOW)

    ; Définit le texte
    For $i = 1 To 50
        $sText &= $i & @CRLF
    Next
    _GUICtrlEdit_SetText($idEdit, $sText)

    ; Scroll
    _GUICtrlStatusBar_SetText($hStatusBar, "Scrolled: " & _GUICtrlEdit_LineScroll($idEdit, 0, _GUICtrlEdit_GetLineCount($idEdit)))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example