UDF > GUI > GuiEdit >

_GUICtrlEdit_SetRECT

Définit le rectangle de mise en forme d'un contrôle d'édition multiligne

#include <GuiEdit.au3>
_GUICtrlEdit_SetRECT ( $hWnd, $aRect )

Paramètres

$hWnd ID/handle du contrôle
$aRect Tableau dans le format suivant:
[0] - Indique la coordonnée x du coin supérieur gauche du rectangle.
[1] - Indique la coordonnée y du coin supérieur gauche du rectangle.
[2] - Indique la coordonnée x du coin inférieur droit du rectangle.
[3] - Indique la coordonnée y du coin inférieur droit du rectangle.

Valeur de retour

Aucune.

En relation

_GUICtrlEdit_SetRECTEx

Exemple

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hStatusBar, $idEdit, $hGUI
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"
    Local $aPartRightSide[6] = [50, 130, 210, 290, 378, -1], $aRect

    ; Crée une GUI
    $hGUI = GUICreate("Edit Set RECT", 400, 300)
    $idEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
    _GUICtrlStatusBar_SetIcon($hStatusBar, 5, 97, "shell32.dll")
    _GUICtrlStatusBar_SetText($hStatusBar, "Rect")
    GUISetState(@SW_SHOW)

    ; Obtient Rect
    $aRect = _GUICtrlEdit_GetRECT($idEdit)
    $aRect[0] += 10
    $aRect[1] += 10
    $aRect[2] -= 10
    $aRect[3] -= 10

    ; Ajoute le texte
    _GUICtrlEdit_AppendText($idEdit, FileRead($sFile))
    _GUICtrlEdit_LineScroll($idEdit, 0, _GUICtrlEdit_GetLineCount($idEdit) * -1)

    ; Définit Rect
    _GUICtrlEdit_SetRECT($idEdit, $aRect)

    ; Obtient Rect
    $aRect = _GUICtrlEdit_GetRECT($idEdit)
    _GUICtrlStatusBar_SetText($hStatusBar, "Left: " & $aRect[0], 1)
    _GUICtrlStatusBar_SetText($hStatusBar, "Topt: " & $aRect[1], 2)
    _GUICtrlStatusBar_SetText($hStatusBar, "Right: " & $aRect[2], 3)
    _GUICtrlStatusBar_SetText($hStatusBar, "Bottom: " & $aRect[3], 4)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example