UDF > GUI > GuiEdit >

_GUICtrlEdit_GetRECT

Obtient le rectangle de mise en forme d'un contrôle d'édition

#include <GuiEdit.au3>
_GUICtrlEdit_GetRECT ( $hWnd )

Paramètre

$hWnd ID/handle du contrôle

Valeur de retour

Retourne un tableau contenant le RECT dans le format suivant:
    [0] - coordonnée X du coin supérieur gauche du rectangle
    [1] - coordonnée Y du coin supérieur gauche du rectangle,
    [2] - coordonnée X du coin inférieur droit du rectangle
    [3] - Coordonnée Y du coin inférieur droit du rectangle

Remarque

Sous certaines conditions, _GUICtrlEdit_GetRECT() pourrait ne pas retourner les valeurs exactes que
_GUICtrlEdit_SetRECT() a définies, elles seront à peu près correctes, mais elles pourront être erronées de quelques pixels.

En relation

_GUICtrlEdit_GetRECTEx

Exemple

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hStatusBar, $idEdit, $hGUI
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"
    Local $aPartRightSide[6] = [50, 130, 210, 290, 378, -1], $aRect

    ; Crée une GUI
    $hGUI = GUICreate("Edit Get RECT", 400, 300)
    $idEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
    _GUICtrlStatusBar_SetIcon($hStatusBar, 5, 97, "shell32.dll")
    _GUICtrlStatusBar_SetText($hStatusBar, "Rect")
    GUISetState(@SW_SHOW)

    ; Obtient Rect
    $aRect = _GUICtrlEdit_GetRECT($idEdit)
    $aRect[0] += 10
    $aRect[1] += 10
    $aRect[2] -= 10
    $aRect[3] -= 10

    ; Définit Rect
    _GUICtrlEdit_SetRECT($idEdit, $aRect)

    ; Ajoute le texte
    _GUICtrlEdit_AppendText($idEdit, FileRead($sFile))
    _GUICtrlEdit_LineScroll($idEdit, 0, _GUICtrlEdit_GetLineCount($idEdit) * -1)

    ; Obtient Rect
    $aRect = _GUICtrlEdit_GetRECT($idEdit)
    _GUICtrlStatusBar_SetText($hStatusBar, "Left: " & $aRect[0], 1)
    _GUICtrlStatusBar_SetText($hStatusBar, "Topt: " & $aRect[1], 2)
    _GUICtrlStatusBar_SetText($hStatusBar, "Right: " & $aRect[2], 3)
    _GUICtrlStatusBar_SetText($hStatusBar, "Bottom: " & $aRect[3], 4)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example