Functions > GUI > GUICtrlCreate >


GUICtrlCreateTabItem

Crée un contrôle -TabItem- dans un contrôle Tab existant.

GUICtrlCreateTabItem ( "text" )

Paramètre

text Le texte du contrôle.

Valeur de retour

Succès: Retourne l'identifiant (controlID) du nouveau contrôle.
Échec: Retourne 0.

Remarques

Pour sélectionner un TabItem spécifique à afficher lorsque la GUI s'ouvre, utilisez GUICtrlSetState(-1, $GUI_SHOW), comme illustré dans l'exemple.

Il est important de fermer la structure Tab en créant un contrôle TabItem final avec un texte null - GUICtrlCreateTabItem("").

Les contrôles pour un TabItem spécifique devraient être créés après le TabItem et avant la création d'une nouveau TabItem ou la fermeture de la structure du Tab. Pour créer un nouveau contrôle dans un TabItem existant, utilisez GUISwitch($hWin, $tabitem) pour choisir le TabItem correct et ensuite créer le nouveau contrôle. N'oubliez pas de fermer la structure TabItem avec GUICtrlCreateTabItem("").

Le contrôle TabItem ne peut être coloré (trop de code ...).

GUICtrlRead() retournera l'index du TabItem cliqué, ou le controlID lorsque le mode avancé est utilisé.

Pour définir ou modifier des informations dans le contrôle, consultez les fonctions GUICtrlUpdate...().

En relation

GUICtrlCreateTab, GUICtrlRead, GUICtrlSetState, GUIEventOptions (Option), GUIGetMsg, GUISwitch

Exemple

#include <GUIConstantsEx.au3>

Example()

Func Example()
    GUICreate("My GUI Tab", 250, 150); Crée une GUI centrée

    GUISetBkColor(0x00E0FFFF)
    GUISetFont(9, 300)

    Local $idTab = GUICtrlCreateTab(10, 10, 200, 100)
    GUICtrlCreateTabItem("tab0")
    GUICtrlCreateLabel("label0", 30, 80, 50, 20)
    GUICtrlCreateButton("OK0", 20, 50, 50, 20)
    GUICtrlCreateInput("default", 80, 50, 70, 20)

    GUICtrlCreateTabItem("tab----1")
    GUICtrlCreateLabel("label1", 30, 80, 50, 20)
    GUICtrlCreateCombo("", 20, 50, 60, 120)
    GUICtrlSetData(-1, "Trids|CyberSlug|Larry|Jon|Tylo|guinness", "Jon");Jon défaut
    GUICtrlCreateButton("OK1", 80, 50, 50, 20)

    GUICtrlCreateTabItem("tab2")
    GUICtrlSetState(-1, $GUI_SHOW); s'affichera en premier
    GUICtrlCreateLabel("label2", 30, 80, 50, 20)
    GUICtrlCreateButton("OK2", 140, 50, 50)

    GUICtrlCreateTabItem(""); fin de la définition de TabItem

    GUICtrlCreateLabel("Click on tab and see the title", 20, 130, 250, 20)

    GUISetState(@SW_SHOW)

    Local $idMsg = GUIGetMsg()
    ; Boucle jusqu'à ce que l'utilisateur quitte.
    While $idMsg <> $GUI_EVENT_CLOSE
        If $idMsg = $idTab Then
            ; Affiche l'onglet cliqué
            WinSetTitle("My GUI Tab", "", "My GUI Tab" & GUICtrlRead($idTab))
        EndIf
        $idMsg = GUIGetMsg()
    WEnd
EndFunc   ;==>Example