Functions > GUI > GUICtrlCreate >

GUICtrlCreateTab

Crée un contrôle Tab pour une GUI.

GUICtrlCreateTab ( left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )

Paramètres

left Coordonnée X du coin supérieur gauche du contrôle. Si -1 est utilisé, X sera calculée en accord avec GUICoordMode.
top Coordonnée Y du coin supérieur gauche du contrôle. Si -1 est utilisé, Y sera calculée en accord avec GUICoordMode.
width [optionnel] Largeur du contrôle (par défaut, la largeur utilisée précédemment).
height [optionnel] Hauteur du contrôle (par défaut, la hauteur précédemment utilisée).
style [optionnel] Définit le style du contrôle. Consultez Annexe des styles des contrôles GUI.
    Par défaut (-1) : aucun.
    Styles forcés : $TCS_TOOLTIPS, $WS_TABSTOP, $WS_CLIPSIBLINGS
exStyle [optionnel] Définit le style étendu du contrôle. Consultez Table des styles étendus.

Valeur de retour

Succès: Retourne l'ID du nouveau contrôle.
Échec: Retourne 0.

Remarques

Un contrôle à onglet Tab est un contrôle qui peut seulement contenir des contrôles TabItem. Tous les autres contrôles devraient être créés dans ces TabItems à l'aide des fonctions GUICtrlCreate... comme dans l'exemple. Il est important de fermer la structure tab en créant un contrôle final TabItem avec un texte null - GUICtrlCreateTabItem("").

Pour définir ou modifier des informations dans le contrôle, consultez les fonctions GUICtrlUpdate...().

Pour combiner des styles avec le style par défaut, utilisez BitOR($ GUI_SS_DEFAULT_TAB, newstyle, ...).
Pour utiliser la valeur par défaut, ajoutez #include <TabConstants.au3> dans votre script.

Le redimensionnement par défaut est $GUI_DOCKSIZE.

Une GUI peut contenir un seul contrôle Tab, mais il est possible de créer des GUI enfants contenant chacune un contrôle Tab.

En relation

GUICoordMode (Option), GUICtrlCreate..., GUICtrlCreateTabItem, GUICtrlUpdate..., GUIGetMsg

Exemple

#include <GUIConstantsEx.au3>

Example()

Func Example()
    GUICreate("My GUI Tab") ; Permet de créer une boîte de dialogue qui s'affichera au centre

    GUISetBkColor(0x00E0FFFF)
    GUISetFont(9, 300)

    GUICtrlCreateTab(10, 10, 200, 100)

    GUICtrlCreateTabItem("tab0")
    GUICtrlCreateLabel("label0", 30, 80, 50, 20)
    GUICtrlCreateButton("OK0", 20, 50, 50, 20)
    GUICtrlCreateInput("default", 80, 50, 70, 20)

    GUICtrlCreateTabItem("tab----1")
    GUICtrlCreateLabel("label1", 30, 80, 50, 20)
    GUICtrlCreateCombo("", 20, 50, 60, 120)
    GUICtrlSetData(-1, "Trids|CyberSlug|Larry|Jon|Tylo|guinness", "Jon") ;Jon défaut
    GUICtrlCreateButton("OK1", 80, 50, 50, 20)

    GUICtrlCreateTabItem("tab2")
    GUICtrlSetState(-1, $GUI_SHOW) ; sera affiché en premier
    GUICtrlCreateLabel("label2", 30, 80, 50, 20)
    GUICtrlCreateButton("OK2", 140, 50, 50)

    GUICtrlCreateTabItem("") ; fin de la définition de TabItem

    GUICtrlCreateLabel("label3", 20, 130, 50, 20)

    GUISetState(@SW_SHOW)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example