Functions > GUI > GUICtrlCreate >

GUICtrlCreateInput

Crée un contrôle Input pour une GUI.

GUICtrlCreateInput ( "text", left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )

Paramètres

text	Le texte du contrôle.
left	La coordonnée X du coin supérieur gauche du contrôle. Si -1 est utilisé alors X sera automatiquement déterminée par GUICoordMode.
top	La coordonnée Y du coin supérieur gauche du contrôle. Si -1 est utilisé alors Y sera automatiquement déterminée par GUICoordMode.
width	[optionnel] Largeur du contrôle (par défaut, la largeur précédemment utilisée).
height	[optionnel] Hauteur du contrôle (par défaut, la hauteur précédemment utilisée).
style	[optionnel] Définit le style du contrôle. Consultez Annexe des styles des contrôles GUI. Par défaut (-1) : $ES_LEFT, $ES_AUTOHSCROLL Styles forcés : $WS_TABSTOP seulement si non $ES_READONLY. $ES_MULTILINE est toujours réinitialisé.
exStyle	[optionnel] Définit le style étendu du contrôle. Consultez Table des styles étendus. Par défaut (-1) : $WS_EX_CLIENTEDGE

Valeur de retour

Succès:	Retourne l'ID du nouveau contrôle.
Échec :	Retourne 0.

Remarques

Pour obtenir la valeur du contrôle, consultez GUICtrlRead.
Pour définir ou changer les informations du contrôle consultez les fonctions GUICtrlUpdate....

Pour définir un contrôle Input afin d'entrer un mot de passe (l'entrée de donnée est cachée par des astérisques) utilisez le style $ES_PASSWORD.

Si vous voulez glisser et déplacer un nom de fichier dans le contrôle, il suffit d'ajouter WS_EX_ACCEPTFILES en style étendu dans la fonction GUICreate() et définir l'état avec $GUI_DROPACCEPTED.

Après de multiple glissés déplacés de fichiers dans ce contrôle, vous pouvez récupérer les noms des fichiers qui sont séparés par '|' avec GUICtrlRead().

Pour utiliser les valeurs définies ci-dessus vous devez inclure #include <EditConstants.au3> dans votre script.

Redimensionnement par défaut : $GUI_DOCKHEIGHT.

En relation

GUICoordMode (Option), GUICtrlCreateUpdown, GUICtrlRead, GUICtrlSetLimit, GUICtrlUpdate..., GUIGetMsg

Exemple

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    GUICreate(" My GUI input acceptfile", 320, 120, @DesktopWidth / 2 - 160, @DesktopHeight / 2 - 45, -1, $WS_EX_ACCEPTFILES)
    Local $idFile = GUICtrlCreateInput("", 10, 5, 300, 20)
    GUICtrlSetState(-1, $GUI_DROPACCEPTED)
    GUICtrlCreateInput("", 10, 35, 300, 20)  ; n'acceptera pas le drag & drop des fichiers
    Local $idBtn = GUICtrlCreateButton("Ok", 40, 75, 60, 20)

    GUISetState(@SW_SHOW)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE Or GUIGetMsg() = $idBtn

    MsgBox($MB_SYSTEMMODAL, "drag drop file", GUICtrlRead($idFile))
EndFunc   ;==>Example