Functions > GUI >


GUISwitch

Commute la fenêtre courante utilisée pour les fonctions GUI.

GUISwitch ( winhandle [, tabitemID] )

Paramètres

winhandle Le handle de la fenêtre à commuter.
tabitemID [optional] ID du contrôle TabItem à sélectionner.

Valeur de retour

Succès: Retourne le handle de la GUI précédente.
Échec: Retourne un handle NULL.

Remarques

Beaucoup de fonctions spécifiques GUI travaillent sur la fenêtre "courante" - ce qui est généralement la dernière fenêtre créée avec GUICreate(). Cette fonction vous permet de construire une autre fenêtre "courante". Ce qui ne signifie pas que la fenêtre référencée sera active. Vous devez utiliser WinActivate().

L'utilisation de l'ID de TabItem permet de créer un nouveau contrôle dans le contrôle TabItem spécifié. Ne pas oublier de fermer la définition de TabItem GUICtrlCreateTabItem("")

En relation

GUICreate, GUICtrlCreateTabItem, GUIDelete

Exemple

#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUIParent1 = GUICreate("Parent1")
    GUICtrlCreateTab(10, 10)
    Local $idTabItem = GUICtrlCreateTabItem("tab1")
    GUICtrlCreateTabItem("tab2")
    GUICtrlCreateTabItem("")

    Local $hGUIParent2 = GUICreate("Parent2", -1, -1, 100, 100)

    GUISwitch($hGUIParent2)
    GUISetState(@SW_SHOW)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUISwitch($hGUIParent1, $idTabItem)
    GUICtrlCreateButton("OK", 50, 50, 50)
    GUICtrlCreateTabItem("")

    GUISetState(@SW_SHOW, $hGUIParent1)
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete($hGUIParent1)
    GUIDelete($hGUIParent2)
EndFunc   ;==>Example