Functions > GUI > GUICtrlCreate >

GUICtrlCreateLabel

Crée un contrôle Label pour une GUI.

GUICtrlCreateLabel ( "text", left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )

Paramètres

text	Le texte du contrôle.
left	La coordonnée X du coin supérieur gauche du contrôle. Si -1 est utilisé alors X sera déterminée en accord avec GUICoordMode.
top	La coordonnée Y du coin supérieur gauche du contrôle. Si -1 est utilisé alors Y sera déterminée en accord avec GUICoordMode.
width	[optionnel] Largeur du contrôle (par défaut, le texte est ajusté en largeur).
height	[optionnel] Hauteur du contrôle (par défaut, le texte est ajusté en hauteur).
style	[optionnel] Définit le style du contrôle. Consultez Annexe des Styles des contrôles. Par défaut (-1) : aucun. Styles forcés : $SS_NOTIFY, $SS_LEFT
exStyle	[optionnel] Définit le style étendu du contrôle. Consultez Table des styles étendus.

Valeur de retour

Succès:	Retourne l'ID du nouveau contrôle.
Échec:	Retourne 0.

Remarques

Pour définir ou modifier des informations dans le contrôle, consultez GUICtrlUpdate ... .

Pour combiner les styles avec le style par défaut, utilisez BitOR($GUI_SS_DEFAULT_LABEL, newstyle, ...).
Pour utiliser les valeurs indiquées ci-dessus, vous devez inclure #include <StaticConstants.au3> dans votre script.

Le redimensionnement par défaut est $GUI_DOCKAUTO, la taille et la position seront modifiée.

Le style étendu $GUI_WS_EX_PARENTDRAG peut être utilisé pour permettre le glissement de la fenêtre parente, pour les fenêtres qui n'ont pas de barre de titre (pas de style $WS_CAPTION avec GUICreate()).

Pour définir le fond transparent, utiliser GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT).

En relation

GUICoordMode (Option), GUICtrlUpdate..., GUIGetMsg

Exemple

#include <GUIConstantsEx.au3>

Example()

Func Example()
    GUICreate("My GUI")  ; Crée une GUI centrée

    GUISetHelp("notepad.exe")  ; Exécute le Bloc-notes si F1 est tapé
    Local $iOldOpt = Opt("GUICoordMode", 2)

    Local $iWidthCell = 70
    GUICtrlCreateLabel("Line 1 Cell 1", 10, 30, $iWidthCell)  ; la première cellule de 70 de large
    GUICtrlCreateLabel("Line 2 Cell 1", -1, 0)  ; ligne suivante
    GUICtrlCreateLabel("Line 3 Cell 2", 0, 0)  ; ligne suivante et cellule suivante
    GUICtrlCreateLabel("Line 3 Cell 3", 0, -1)  ; cellule suivante même ligne
    GUICtrlCreateLabel("Line 4 Cell 1", -3 * $iWidthCell, 0)  ; ligne suivante Cell1

    GUISetState(@SW_SHOW)  ; Affiche la GUI

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    $iOldOpt = Opt("GUICoordMode", $iOldOpt)
EndFunc   ;==>Example