Functions > GUI > GUICtrlCreate >


GUICtrlCreateButton

Crée un contrôle Button pour une GUI.

GUICtrlCreateButton ( "text", left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )

Paramètres

text Texte du bouton.
left Coordonnée X du coin supérieur gauche. Si -1 est utilisé alors X sera automatiquement déterminée par GUICoordMode.
top Coordonnée Y du coin supérieur gauche. Si -1 est utilisé alors Y sera automatiquement déterminée par GUICoordMode.
width [optionnel] Largeur du bouton (Le texte par défaut se met à l'échelle).
height [optionnel] Hauteur du bouton (Le texte par défaut se met à l'échelle).
style [optionnel] Définit le style du bouton. Consultez Styles de GUI.
    Par défaut ( -1) : aucun style.
    Styles forcés : $WS_TABSTOP
exStyle [optionnel] Définit les styles étendus. Consultez Styles étendus.
    Par défaut (-1) : $WS_EX_WINDOWEDGE

Valeur de retour

Succès: Retourne l'ID du nouveau contrôle.
Échec: Retourne 0.

Remarques

Pour voir ou changer les informations du bouton, consultez GUICtrlUpdate....

Un bouton peut afficher une icône ou un bouton en utilisant les styles $BS_ICON ou $BS_BITMAP. Utiliser GUICtrlSetImage pour spécifier l'image à utiliser.

Pour combiner des styles avec ceux par défaut, utiliser BitOR($GUI_SS_DEFAULT_BUTTON, nouveaustyle,...).
Pour utiliser les valeurs spécifiées ci-dessus, vous devez inclure #include <ButtonConstants.au3> dans votre script.
Le redimensionnement par défaut est $GUI_DOCKSIZE.

En relation

GUICoordMode (Option), GUICtrlUpdate..., GUIGetMsg

Exemple

#include <GUIConstantsEx.au3>

Example()

Func Example()
    ; Crée une GUI avec différents contrôles.
    Local $hGUI = GUICreate("Example", 300, 200)

    ; Crée deux contrôles bouton.
    Local $idNotepad = GUICtrlCreateButton("Run Notepad", 120, 170, 85, 25)
    Local $idClose = GUICtrlCreateButton("Close", 210, 170, 85, 25)

    ; Affiche la GUI.
    GUISetState(@SW_SHOW, $hGUI)

    Local $iPID = 0, $idMsg = GUIGetMsg()

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    While ($idMsg <> $GUI_EVENT_CLOSE) And ($idMsg <> $idClose)
        If $idMsg = $idNotepad Then
            ; Exécute le Bloc-notes avec la fenêtre agrandie au maximum.
            $iPID = Run("notepad.exe", "", @SW_SHOWMAXIMIZED)
        EndIf
        $idMsg = GUIGetMsg()
    WEnd

    ; Supprime la GUI précédente et tous ses contrôles.
    GUIDelete($hGUI)

    ; Ferme le processus Notepad en utilisant le PID renvoyée par Run.
    If $iPID > 0 Then ProcessClose($iPID)
EndFunc   ;==>Example