UDF > GUI > GuiToolTip >

_GUIToolTip_SetMargin

Définit les marges gauche, supérieure, droite, et inférieure d'un contrôle info-bulle

#include <GuiToolTip.au3>
_GUIToolTip_SetMargin ( $hWnd, $iLeft, $iTop, $iRight, $iBottom )

Paramètres

$hWnd Handle du contrôle info-bulle (retourné par _GUIToolTip_Create.)
$iLeft Distance entre la bordure gauche et la partie gauche du texte, en pixels
$iTop Distance entre la bordure supérieure et l'extrémité supérieure du texte, en pixels
$iRight Distance entre la bordure droite et la partie droite du texte, en pixels
$iBottom Distance entre la bordure inférieure et le bas du texte, en pixels

Valeur de retour

Aucune.

En relation

_GUIToolTip_GetMargin

Exemple

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>
#include <MsgBoxConstants.au3>
#include <WinAPITheme.au3>

Example()

Func Example()
    Local $hGUI = GUICreate(StringTrimRight(@ScriptName, StringLen(".exe")), 350, 200)

    Local $idButton = GUICtrlCreateButton("Button ToolTip", 30, 32, 130, 28)
    Local $hButton = GUICtrlGetHandle($idButton)
    ; Crée un contrôle info-bulle
    Local $hToolTip1 = _GUIToolTip_Create(0)
    ; Si vous utilisez un paramètre de thème Windows, il est désactivé pour que l'info-bulle
    ; soit affichée, ainsi vous pouvez modifier les marges et voir le changement
    _WinAPI_SetWindowTheme($hToolTip1, "", "")

    Local $hToolTip2 = _GUIToolTip_Create(0)
    _WinAPI_SetWindowTheme($hToolTip2, "", "")
    ; Ceci n'est utilisé que parce que l'info-bulle est un outil multiligne, 
    ; vous n'avez pas besoin de cela pour changer les marges    
    _GUIToolTip_SetMaxTipWidth($hToolTip1, 400)
    _GUIToolTip_SetMaxTipWidth($hToolTip2, 400)

    ; Définit les marges manuellement à la place des paramètres par défaut.
    _GUIToolTip_SetMargin($hToolTip1, 30, 10, 20, 12)

    Local $aMargins = _GUIToolTip_GetMargin($hToolTip1)
    Local $aMargins1 = _GUIToolTip_GetMargin($hToolTip2)

    ; Ajoute un élément déclencheur au premier contrôle info-bulle
    _GUIToolTip_AddTool($hToolTip1, 0, 'Left : ' & $aMargins[0] & @LF & _
            'Top : ' & $aMargins[1] & @LF & _
            'Right : ' & $aMargins[2] & @LF & _
            'Bottom : ' & $aMargins[3], $hButton)
    _GUIToolTip_SetTitle($hToolTip1, "This is the ToolTip with manually set margins")
    ; Add a tool to the second tooltip control
    _GUIToolTip_AddTool($hToolTip2, 0, 'Left : ' & $aMargins1[0] & @LF & _
            'Top : ' & $aMargins1[1] & @LF & _
            'Right : ' & $aMargins1[2] & @LF & _
            'Bottom : ' & $aMargins1[3], $hGUI)
    _GUIToolTip_SetTitle($hToolTip2, "This is the ToolTip with default margins")
    GUISetState(@SW_SHOW)
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    
    ; Détruit le contrôle info-bulle
    _GUIToolTip_Destroy($hToolTip1)
    GUIDelete($hGUI)
EndFunc   ;==>Example