UDF > GUI > GuiToolTip >

_GUIToolTip_SetTitle

Ajoute une icône standard et une chaîne titre

#include <GuiToolTip.au3>
_GUIToolTip_SetTitle ( $hWnd, $sTitle [, $iIcon = 0] )

Paramètres

$hWnd Handle du contrôle info-bulle (retourné par _GUIToolTip_Create.)
$sTitle Chaîne titre
$iIcon [optionnel] Doit prendre l'une des valeurs ci-dessous:
    $TTI_NONE (0) - Pas d'icône [par défaut]
    $TTI_INFO (1) - Icône Information
    $TTI_WARNING (2) - Icône Attention
    $TTI_ERROR (3) - Icône Erreur
    $TTI_INFO_LARGE (4) - Icône Large Information
    $TTI_WARNING_LARGE (5) - Icône large Avertissement
    $TTI_ERROR_LARGE (6) - Icône large Erreur

Les constantes sont définies dans ToolTipConstants.au3

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarque

Avec Windows XP SP2 et les versions ultérieures, $iIcon peut contenir une valeur HICON. Toute valeur supérieure à 3 est supposée être une HICON.
Le titre d'une info-bulle apparaît au-dessus du texte, dans une police différente. Il ne suffit pas d'avoir un titre; l'info-bulle doit avoir aussi un texte, sinon il ne s'affiche pas.
Un titre avec une icône, mais aucun texte dans le titre n'affichera pas le titre ou l'icône. Vous devez définir le texte du titre, même si c'est seulement un caractère, si vous prévoyez d'utiliser une icône.
La chaîne d'entrée dans $sTitle ne doit pas dépasser 99 caractères.

En relation

_GUIToolTip_GetTitleText, _GUIToolTip_UpdateTipText

Exemple

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>

Example()

Func Example()
    Local $hGUI = GUICreate(StringTrimRight(@ScriptName, StringLen(".exe")), 350, 200)

    Local $idAdd = GUICtrlCreateButton("Button", 30, 32, 130, 28)
    Local $hAdd = GUICtrlGetHandle($idAdd)

    ; Crée un contrôle info-bulle
    Local $hToolTip = _GUIToolTip_Create($hGUI)

    ; Ajoute un élément au contrôle info-bulle
    _GUIToolTip_AddTool($hToolTip, 0, "Ceci est le texte du ToolTip", $hAdd)

    ; Définit le titre de l'info-bulle
    _GUIToolTip_SetTitle($hToolTip, 'Ceci est le titre du ToolTip', $TTI_INFO)

    GUISetState(@SW_SHOW)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
   
    ; Détruit le contrôle info-bulle
    _GUIToolTip_Destroy($hToolTip)
    GUIDelete($hGUI)
EndFunc   ;==>Example