UDF > GUI > GuiToolTip >

_GUIToolTip_Destroy

Supprime un contrôle info-bulle

#include <GuiToolTip.au3>
_GUIToolTip_Destroy ( ByRef $hWnd )

Paramètre

$hWnd Handle du contrôle info-bulle (retourné par _GUIToolTip_Create.)

Valeur de retour

Succès: Retourne True, $hWnd est défini à 0.
Échec: Retourne False, et @error est défini à:
        1 - Non autorisé à détruire un contrôle(s) d'une autre application
        2 - $hWnd n'est pas le handle d'un contrôle info-bulle

Remarque

Fonction réservée uniquement aux contrôles ToolTip créés avec _GUIToolTip_Create.

En relation

_GUIToolTip_Create

Exemple

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>
; Click the button to destroy the tooltip control
Example()

Func Example()
    Local $hGUI = GUICreate(StringTrimRight(@ScriptName, StringLen(".exe")), 350, 200)

    Local $idButton = GUICtrlCreateButton("This is a button", 30, 32, 130, 28)
    Local $hButton = GUICtrlGetHandle($idButton)
    ; Crée un contrôle info-bulle avec les paramètres par défaut
    Local $hToolTip = _GUIToolTip_Create(0)

    ; Ajoute un élément au contrôle info-bulle
    _GUIToolTip_AddTool($hToolTip, 0, "This is a ToolTip", $hButton)
    _GUIToolTip_AddTool($hToolTip, 0, "ToolTip text for the GUI", $hGUI)
    GUISetState(@SW_SHOW)

    Local $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        if $iMsg = $idButton Then
            ; Détruit le contrôle info-bulle
            _GUIToolTip_Destroy($hToolTip)
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    ; Détruit le contrôle info-bulle (Dans le cas où le bouton n'a pas encore été actionné)
    _GUIToolTip_Destroy($hToolTip)
    GUIDelete($hGUI)
EndFunc   ;==>Example