UDF > GUI > GuiToolTip >

_GUIToolTip_SetMaxTipWidth

Définit la largeur maximale d'une fenêtre d'info-bulle

#include <GuiToolTip.au3>
_GUIToolTip_SetMaxTipWidth ( $hWnd, $iWidth )

Paramètres

$hWnd Handle du contrôle info-bulle (retourné par _GUIToolTip_Create.)
$iWidth La largeur maximale de la fenêtre d'info-bulle à définir (en pixels)

Valeur de retour

Retourne la largeur maximale précédente d'info-bulle, en pixels.

Remarques

La valeur maximale de la largeur d'info-bulle n'indique pas la largeur réelle d'une fenêtre d'info-bulle.
Au contraire, si une chaîne d'info-bulle est supérieure à la largeur maximale, le contrôle coupe le texte en plusieurs lignes, en utilisant des espaces pour déterminer les sauts de ligne.
Si le texte ne peut pas être segmenté en plusieurs lignes, il est affiché sur une seule ligne.
La longueur de cette ligne peut dépasser la largeur maximum d'info-bulle.

Un contrôle d'info-bulle a besoin de cette option si vous voulez avoir une info-bulle multi- ligne. Sans ce paramètre, si vous mettez un saut de ligne (CR, LF, CRLF) dans le texte d'une bulle, le texte sera tronqué à ce saut de ligne.

En relation

_GUIToolTip_GetMaxTipWidth

Exemple

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>

Example()

Func Example()
    Local $hGUI = GUICreate(StringTrimRight(@ScriptName, StringLen(".exe")), 350, 200)

    Local $idButton = GUICtrlCreateButton("Button ToolTip", 30, 32, 130, 28)
    Local $hButton = GUICtrlGetHandle($idButton)

    ; Crée un contrôle info-bulle
    Local $hToolTip = _GUIToolTip_Create($hGUI)
    ; Définit la largeur maximum à 400 pixels
    _GUIToolTip_SetMaxTipWidth($hToolTip, 400)
    ; Ajoute un élément multi-line au contrôle info-bulle en utilisant @CRLF pour couper le texte en deux lignes
    _GUIToolTip_AddTool($hToolTip, 0, 'Si le texte excède la largeur, alors il continue sur la ligne suivante.' & @CRLF & 'Vous pouvez aussi utiliser @CRLF', $hButton)
    ; Ajoute un élément multi-line au contrôle info-bulle en utilisant le paramètre MaxTipWidth pour couper le texte en deux lignes.
    _GUIToolTip_AddTool($hToolTip, 0, 'Si le texte excède la largeur, alors il continue sur la ligne suivante. Vous pouvez aussi utiliser @CRLF', $hGUI)
    GUISetState(@SW_SHOW)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    
    ; Détruit le contrôle info-bulle
    _GUIToolTip_Destroy($hToolTip)
    GUIDelete($hGUI)
EndFunc   ;==>Example