UDF > GUI > GuiToolTip >

_GUIToolTip_Create

Crée un contrôle info-bulle

#include <GuiToolTip.au3>
_GUIToolTip_Create ( $hWnd [, $iStyle = $_TT_ghTTDefaultStyle] )

Paramètres

$hWnd Handle de la fenêtre qui sera propriétaire du contrôle info-bulle. Voir Remarques.
$iStyle [optionnel] Style de l'info-bulle:
    $TTS_ALWAYSTIP (0x01) - Indique que le contrôle info-bulle apparaît lorsque le curseur est sur un outil, même si la fenêtre propriétaire du contrôle info-bulle est inactive. Sans ce style, l'info-bulle apparaît uniquement lorsque la fenêtre propriétaire de l'outil est active.
    $TTS_NOPREFIX (0x02) - Empêche le système de couper le caractère esperluette dans une chaîne. Sans ce style le système supprime automatiquement les caractères esperluette. Cela autorise une application à utiliser la même chaîne à la fois comme un élément de menu et sous forme de texte dans un contrôle d'info-bulle.
    $TTS_NOANIMATE (0x10) - Désactive l'animation de glissement de l''info-bulle.
    $TTS_NOFADE (0x20) - Désactive l'animation de fondu de l'info-bulle.
    $TTS_BALLOON (0x40) - Indique que le contrôle info-bulle a l'apparence d'une bulle d'un dessin animé
    $TTS_CLOSE (0x80) - Affiche une icône de fermeture de sorte que l'info-bulle peut être annulée

Par défaut: $_TT_ghTTDefaultStyle = BitOr($TTS_ALWAYSTIP, $TTS_NOPREFIX)
Les constantes sont définies dans ToolTipConstants.au3

Valeur de retour

Succès: Retourne le handle du contrôle info-bulle.
Échec: Retourne 0.

Remarque

$hWnd est généralement défini à zéro (0), ou avec le handle de la fenêtre mère ou du propriétaire de la fenêtre en cours de création. Pour créer une fenêtre enfant ou une fenêtre propriétaire, fournissez un handle de fenêtre valide.

En relation

_GUIToolTip_Destroy

Exemple

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>

Example()

Func Example()
    Local $hGUI = GUICreate(StringTrimRight(@ScriptName, StringLen(".exe")), 270, 200)

    Local $idButton_Add = GUICtrlCreateButton("Add", 30, 32, 75, 25)
    Local $hButton_Add = GUICtrlGetHandle($idButton_Add)

    Local $idButton_Clear = GUICtrlCreateButton("Clear", 30, 72, 75, 25)
    Local $hButton_Clear = GUICtrlGetHandle($idButton_Clear)

    Local $idMylist = GUICtrlCreateList("Item 1", 120, 32, 121, 97)
    Local $hMylist = GUICtrlGetHandle($idMylist)

    Local $idButton_Close = GUICtrlCreateButton("Exit button", 80, 150, 110, 28)
    Local $hButton_Close = GUICtrlGetHandle($idButton_Close)

    ; Crée 2 contrôles info-bulle
    Local $hToolTip1 = _GUIToolTip_Create(0, BitOR($_TT_ghTTDefaultStyle, $TTS_BALLOON)); Info-bulle de style balloon
    Local $hToolTip2 = _GUIToolTip_Create(0) ; Info-bulle de style par défaut
    _GUIToolTip_SetMaxTipWidth($hToolTip2, 100) ; Définit l'option multiline pour l'info-bulle $hToolTip2
    ; Ajoute des outils aux contrôles info-bulle
    _GUIToolTip_AddTool($hToolTip1, 0, "Ajoute un élément à la liste", $hButton)
    _GUIToolTip_AddTool($hToolTip1, 0, "Quitte le script", $hClose)
    _GUIToolTip_AddTool($hToolTip1, 0, "La listbox", $hMylist)
    _GUIToolTip_AddTool($hToolTip2, 0, "Efface la liste", $hClear)
    _GUIToolTip_AddTool($hToolTip2, 0, "Info-bulle Multiligne" & @CRLF & "pour la GUI", $hGUI) ; Info-bulle multiligne
    GUISetState(@SW_SHOW)
    
    Local $iMsg
    Do
        $iMsg = GUIGetMsg()
        Switch $iMsg
            Case $idButton_Add
                GUICtrlSetData($idMylist, 'Le bouton Add a été pressé"|')
            Case $idButton_Clear
                GUICtrlSetData($idMylist, '')
        EndSwitch
    Until $iMsg = $idButton_Close Or $iMsg = $GUI_EVENT_CLOSE
 
    ; Détruit les contrôles info-bulle
    _GUIToolTip_Destroy($hToolTip1)
    _GUIToolTip_Destroy($hToolTip2)
    GUIDelete($hGUI)
EndFunc   ;==>Example