UDF > GUI > GuiToolTip >

_GUIToolTip_AddTool

Enregistre un élément déclencheur d'info-bulle

#include <GuiToolTip.au3>
_GUIToolTip_AddTool ( $hTool, $hWnd, $sText [, $iID = 0 [, $iLeft = 0 [, $iTop = 0 [, $iRight = 0 [, $iBottom = 0 [, $iFlags = Default [, $iParam = 0]]]]]]] )

Paramètres

$hTool Handle du contrôle info-bulle (retourné par _GUIToolTip_Create.)
$hWnd Handle de la fenêtre qui contient l'élément, ou 0
$sText Texte pour le contrôle info-bulle. Voir Remarques.
$iID [optionnel] Identifiant de l'élément déclencheur, ou handle Window du contrôle auquel l'élément doit être assigné
$iLeft [optionnel] Coordonnée X du coin supérieur gauche du rectangle
$iTop [optionnel] Coordonnée Y du coin supérieur gauche du rectangle
$iRight [optionnel] Coordonnée X du coin inférieur droit du rectangle
$iBottom [optionnel] Coordonnée Y du coin inférieur droit du rectangle
$iFlags [optionnel] Flags qui contrôlent l'affichage des info-bulle:
    $TTF_IDISHWND - Indique que $iID est le handle d'une fenêtre ou d'un contrôle, à la place de l'identifiant de l'élément déclencheur
    $TTF_CENTERTIP - Centre l'info-bulle au dessous du contrôle spécifié par $iID
    $TTF_RTLREADING - Indique que le texte sera affiché dans la direction opposée de la fenêtre parente (voir Remarques)
    $TTF_SUBCLASS - Indique que le contrôle doit prendre le dessus sur la fenêtre de l'élément
    $TTF_TRACK - Positionne le cadre de l'info-bulle à côté de l'élément qui lui correspond
    $TTF_ABSOLUTE - Positionne le cadre aux mêmes coordonnées que celles fournies par TTM_TRACKPOSITION. (Voir remarques)
    $TTF_TRANSPARENT - Force le contrôle à transmettre les messages de la souris à la fenêtre parente
    $TTF_PARSELINKS - Indique que les liens dans le texte du contrôle doivent être affichés en tant que liens

Par défaut = BitOr($TTF_SUBCLASS, $TTF_IDISHWND)
Les constantes sont définies dans ToolTipConstants.au3
$iParam [optionnel] Valeur définie par l'application qui est associée à l'élément déclencheur

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarques

Si un rappel de notification est nécessaire, vous devez définir $sText = -1 (LPSTR_TEXTCALLBACK).

Si vous utilisez le flag $TTF_IDISHWND, alors les coordonnées $iLeft, $iTop, $$iRight et iBottom sont ignorées.

Si vous utilisez le flag $TTF_ABSOLUTE, il doit être utilisée avec le paramètre $TTF_TRACK.
Les fenêtres normales affichent le texte de gauche à droite (LTR). Windows peut afficher des langues comme l'hébreu ou l'arabe qui lisent de droite à gauche (RTL). Normalement, le texte de l'info-bulle s'affiche dans le même sens que le texte dans sa fenêtre parent. Si $TTF_RTLREADING est activé, le texte de l'info-bulle sera lu dans le sens opposé par rapport au texte de la fenêtre parent.

En relation

_GUIToolTip_DelTool

Exemples

Exemple 1

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>

Example()

Func Example()
    Local $hGUI = GUICreate(StringTrimRight(@ScriptName, StringLen(".exe")), 350, 200)

    Local $idButton = GUICtrlCreateButton("This is a button", 30, 32, 130, 28)
    Local $hButton = GUICtrlGetHandle($idButton)
    ; Crée un contrôle info-bulle avec les paramètres par défaut
    Local $hToolTip = _GUIToolTip_Create(0)

    ; Ajoute un élément déclencheur au contrôle info-bulle
    _GUIToolTip_AddTool($hToolTip, 0, "This is a ToolTip", $hButton)
    GUISetState(@SW_SHOW)

    While GUIGetMsg() <> $GUI_EVENT_CLOSE
    WEnd

    ; Détruit le contrôle info-bulle
    _GUIToolTip_Destroy($hToolTip)
    GUIDelete($hGUI)
EndFunc   ;==>Example

Exemple 2

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>
#include <StaticConstants.au3>

; Cet exemple montre comment ajouter un outil, il n'assigne pas l'outil à un contrôle, justa à une zone de la GUI
Example()

Func Example()
    Local $hGUI = GUICreate(StringTrimRight(@ScriptName, StringLen(".exe")), 350, 200) 
    ; Crée des cadres pour indiquer où l'info-bulle s'affichera lorsque la souris sera à
    ; l'emplacement correct dans la GUI, ces cadres ne sont pas assignés à une info-bulle
    ; Ces cadres sont SEULEMENT pour la représentation visuelle de l'endroit où l'info-bulle s'affichera,
    ; Ils ne sont pas nécessaires pour afficher l'info-bulle.
    GUICtrlCreateLabel("", 10, 10, 160, 75, $SS_ETCHEDFRAME)
    ; Ce contrôle label doit être désactivé, sinon l'info-bulle ne s'affichera pas quand la 
    ; souris le survolera.
    GUICtrlSetState(-1, $GUI_DISABLE)
    GUICtrlCreateLabel("", 10, 84, 160, 75, $SS_ETCHEDFRAME)
    ; Ce contrôle label doit être désactivé, sinon l'info-bulle ne s'affichera pas quand la 
    ; souris le survolera.
    GUICtrlSetState(-1, $GUI_DISABLE)
    GUICtrlCreateLabel("", 169, 10, 160, 75, $SS_ETCHEDFRAME)
    ; Ce contrôle label doit être désactivé, sinon l'info-bulle ne s'affichera pas quand la 
    ; souris le survolera.    
    GUICtrlSetState(-1, $GUI_DISABLE)
    GUICtrlCreateLabel("", 169, 84, 160, 75, $SS_ETCHEDFRAME)
    ; Ce contrôle label doit être désactivé, sinon l'info-bulle ne s'affichera pas quand la 
    ; souris le survolera.
    GUICtrlSetState(-1, $GUI_DISABLE)
    Local $idButton = GUICtrlCreateButton("Ceci est un bouton", 30, 32, 130, 28)
    Local $hButton = GUICtrlGetHandle($idButton)
    ; Crée un contrôle info-bulle avec les paramètres par défaut
    Local $hToolTip = _GUIToolTip_Create(0)

    ; Ajoute 4 éléments déclencheurs au contrôle info-bulle, ces éléments sont créés en utilisant des positions sur la GUI
    ; plutôt qu'en les assignant à un contrôle spécifique
    _GUIToolTip_AddTool($hToolTip, $hGUI, "Coin supérieur gauche", 0, 10, 10, 168, 85, $TTF_SUBCLASS)
    _GUIToolTip_AddTool($hToolTip, $hGUI, "Coin supérieur droit", 0, 168, 10, 328, 85, $TTF_SUBCLASS)
    _GUIToolTip_AddTool($hToolTip, $hGUI, "Coin inférieur gauche", 0, 10, 85, 168, 160, $TTF_SUBCLASS)
    _GUIToolTip_AddTool($hToolTip, $hGUI, "Coin inférieur droit", 0, 168, 85, 328, 160, $TTF_SUBCLASS)
    ; Ajoute un élément déclencheur au contrôle info-bulle qui est assigné au contrôle bouton
    _GUIToolTip_AddTool($hToolTip, 0, "This tooltip belongs to the button", $hButton)
    GUISetState(@SW_SHOW)

    While GUIGetMsg() <> $GUI_EVENT_CLOSE
    WEnd

    ; Détruit le contrôle info-bulle
    _GUIToolTip_Destroy($hToolTip)
    GUIDelete($hGUI)
EndFunc   ;==>Example