UDF > GUI > GuiToolTip >

_GUIToolTip_DelTool

Supprime un élément déclencheur du contrôle info-bulle

#include <GuiToolTip.au3>
_GUIToolTip_DelTool ( $hWnd, $hTool [, $iID = 0] )

Paramètres

$hWnd Handle du contrôle info-bulle (retourné par _GUIToolTip_Create.)
$hTool Handle de la fenêtre qui contient l'élément (voir Remarques)
$iID [optionnel] Handle de l'élément à supprimer (voir Remarques)

Valeur de retour

Aucune.

Remarque

Utilisez les mêmes paramètres pour $hTool et $iID qui ont été utilisés pour créer l'élément à l'aide _GUIToolTip_AddTool()

En relation

_GUIToolTip_AddTool

Exemple

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>

Example()

Func Example()
    Local $hGUI = GUICreate(StringTrimRight(@ScriptName, StringLen(".exe")), 350, 200)

    Local $idButton = GUICtrlCreateButton("This is a button", 30, 32, 130, 28)
    Local $hButton = GUICtrlGetHandle($idButton)
    ; Crée un contrôle info-bulle avec les paramètres par défaut
    Local $hToolTip = _GUIToolTip_Create(0)
    _GUIToolTip_SetMaxTipWidth($hToolTip, 400)
    ; Ajoute un élément au contrôle info-bulle
    _GUIToolTip_AddTool($hToolTip, 0, "Cliquez ici pour supprimer l'info-bulle" & @CRLF & "pour ce bouton", $hButton)
    _GUIToolTip_AddTool($hToolTip, 0, "ToolTip text for the GUI", $hGUI)
    GUISetState(@SW_SHOW)

    Local $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idButton Then
            ; Supprime l'info-bulle assignée au bouton, mais pas le contrôle info-bulle
            ; ni l'info-bulle assignée à la GUI
            _GUIToolTip_DelTool($hToolTip, 0, $hButton)
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    ; Détruit le contrôle info-bulle
    _GUIToolTip_Destroy($hToolTip)
    GUIDelete($hGUI)
EndFunc   ;==>Example