UDF > GUI > GuiImageList >

_GUIImageList_SetIconSize

Définit les dimensions des images d'une liste d'images et supprime toutes les images dans la liste

#include <GuiImageList.au3>
_GUIImageList_SetIconSize ( $hWnd, $iCX, $iCY )

Paramètres

$hWnd Handle de la liste d'images
$iCX La largeur, en pixels, des images de la liste d'images
$iCY La hauteur, en pixels, des images de la liste d'images

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarque

Toutes les images d'une liste d'images ont les mêmes dimensions.

En relation

_GUIImageList_GetIconSize

Exemple

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hImage, $aSize, $idListview

    GUICreate("ImageList Set Icon Size", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 199, BitOR($LVS_SHOWSELALWAYS, $LVS_NOSORTHEADER, $LVS_REPORT))
    $g_idMemo = GUICtrlCreateEdit("", 2, 200, 396, 266, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    $hImage = _GUIImageList_Create(32, 32, 5, 3)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110, True)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131, True)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165, True)
    _GUICtrlListView_SetImageList($idListview, $hImage, 1)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($idListview, "Column 1", 120)
    _GUICtrlListView_AddColumn($idListview, "Column 2", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 3", 100)

    ; Ajoute des éléments
    _GUICtrlListView_AddItem($idListview, "Row 1: Col 1", 0)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 2", 1, 1)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 3", 2, 2)
    _GUICtrlListView_AddItem($idListview, "Row 2: Col 1", 1)
    _GUICtrlListView_AddSubItem($idListview, 1, "Row 2: Col 2", 1, 2)

    ; Affiche la taille des icônes de la liste d'images
    $aSize = _GUIImageList_GetIconSize($hImage)
    MemoWrite("Image width : " & $aSize[0])
    MemoWrite("Image height: " & $aSize[1])

    MsgBox($MB_SYSTEMMODAL, "Information", "Changing Icon Size")

    _GUIImageList_SetIconSize($hImage, 16, 16)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
    _GUICtrlListView_SetImageList($idListview, $hImage, 1)

    $aSize = _GUIImageList_GetIconSize($hImage)
    MemoWrite("Image width : " & $aSize[0])
    MemoWrite("Image height: " & $aSize[1])

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite