UDF > GUI > GuiListView >

_GUICtrlListView_SetImageList

Attache une liste d'images au contrôle

#include <GuiListView.au3>
_GUICtrlListView_SetImageList ( $hWnd, $hHandle [, $iType = 0] )

Paramètres

$hWnd ID/handle du contrôle
$hHandle Handle de la liste d'image à attacher au contrôle
$iType [optionnel] Type de liste de l'images:
    0 - Liste d'images avec de grandes icônes
    1 - Liste d'images avec de petites icônes
    2 - Liste d'images avec des images d'état

Valeur de retour

Succès: Retourne le handle de la liste d'images précédente.
Échec: Retourne 0.

Remarque

La liste d'images actuelle sera détruite lorsque le contrôle sera détruit, sauf si vous définissez le style $LVS_SHAREIMAGELISTS.
Si vous utilisez cette fonction pour remplacer une liste d'images par une autre, votre application doit explicitement détruire toutes les listes d'images autres que l'actuelle.

En relation

_GUICtrlListView_GetImageList

Exemple

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hImage, $idListview

    GUICreate("ListView Set Image List", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Charge les images
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x0000FF, 16, 16))
    Local $hPrevImageList = _GUICtrlListView_SetImageList($idListview, $hImage, 1)

    MsgBox($MB_SYSTEMMODAL, "Information", "Previous Image List Handle: 0x" & Hex($hPrevImageList) & @CRLF & _
            "IsPtr = " & IsPtr($hPrevImageList) & " IsHWnd = " & IsHWnd($hPrevImageList))

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($idListview, "Column 1", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 2", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 3", 100)

    ; Ajoute des éléments
    _GUICtrlListView_AddItem($idListview, "Item 1", 0)
    _GUICtrlListView_AddItem($idListview, "Item 2", 1)
    _GUICtrlListView_AddItem($idListview, "Item 3", 2)

    ; Obtient le handle de la liste d'images
    MsgBox($MB_SYSTEMMODAL, "Information", "Image List Handle: 0x" & Hex(_GUICtrlListView_GetImageList($idListview, 1)))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example