UDF > GUI > GuiListView >

_GUICtrlListView_AddColumn

Ajoute une nouvelle colonne dans le contrôle

#include <GuiListView.au3>
_GUICtrlListView_AddColumn ( $hWnd, $sText [, $iWidth = 50 [, $iAlign = -1 [, $iImage = -1 [, $bOnRight = False]]]] )

Paramètres

$hWnd ID/handle du contrôle
$sText Texte d'en-tête de la colonne à ajouter
$iWidth [optionnel] Largeur de la colonne, en pixels
$iAlign [optionnel] Alignement de l'en-tête de la colonne et du texte du sous-élément de la colonne :
    0 - Le texte est aligné à gauche
    1 - Le texte est aligné à droite
    2 - Le texte est centré
$iImage [optionnel] Index, de base 0, d'une image dans la liste d'images
$bOnRight [optionnel] Si True, l'image relative à la colonne apparaît à droite du texte

Valeur de retour

Succès: Retourne l'index de la nouvelle colonne.
Échec: Retourne -1.

Remarque

L'alignement de la colonne le plus à gauche est toujours justifié à gauche.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>

Example()

Func Example()
    Local $hImage, $idListview

    ; Crée une GUI
    GUICreate("ListView Add Column", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)

    ; Active les styles étendus pour le contrôle
    _GUICtrlListView_SetExtendedListViewStyle($idListview, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES))
    GUISetState(@SW_SHOW)

    ; Charge des images
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListview), 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListview), 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListview), 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($idListview, $hImage, 1)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($idListview, "Column 1", 110)
    _GUICtrlListView_AddColumn($idListview, "Column 2", 110)
    _GUICtrlListView_AddColumn($idListview, "Column 3", 110)

    ; Ajoute des éléments
    _GUICtrlListView_AddItem($idListview, "Row 1: Col 1", 0)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 2", 1, 1)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 3", 2, 2)
    _GUICtrlListView_AddItem($idListview, "Row 2: Col 1", 1)
    _GUICtrlListView_AddSubItem($idListview, 1, "Row 2: Col 2", 1, 2)
    _GUICtrlListView_AddItem($idListview, "Row 3: Col 1", 2)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example