UDF > GUI > GuiImageList >

_GUIImageList_Create

Crée un contrôle ImageList - Liste d'images

#include <GuiImageList.au3>
_GUIImageList_Create ( [$iCX = 16 [, $iCY = 16 [, $iColor = 4 [, $iOptions = 0 [, $iInitial = 4 [, $iGrow = 4]]]]]] )

Paramètres

$iCX [optionnel] Largeur, en pixels, de chaque image
$iCY [optionnel] Hauteur, en pixels, de chaque image
$iColor [optionnel] Profondeur des couleurs de l'image:
    0 - Utilise le comportement par défaut
    1 - Utilise une section DIB 4 bits
    2 - Utilise une section DIB 8 bits
    3 - Utilise une section DIB 16 bits
    4 - Utilise une section DIB 24 bits
    5 - Utilise une section DIB 32 bits
    6 - Utilise une image bitmap dépendant du périphérique
$iOptions [optionnel] Flags des options: peut être une combinaison des éléments suivants:
    1 - Utilise un masque
    2 - Les images de la liste sont mises en miroir
    4 - La liste d'image contient une bande d'images
$iInitial [optionnel] Nombre d'images contenues initialement dans la liste d'images
$iGrow [optionnel] Nombre d'images dont la liste d'images peut augmenter lorsque le système a besoin de place pour de nouvelles images. Ce paramètre représente le nombre de nouvelles images que la liste redimensionnée d'images peut contenir.

Valeur de retour

Succès: Retourne le handle du nouveau contrôle.
Échec: Retourne 0.

En relation

_GUIImageList_Destroy

Exemple

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <WinAPIGdi.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $idListview, $hImage
    Local $iStylesEx = BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES)

    GUICreate("ImageList Create", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268, BitOR($LVS_SHOWSELALWAYS, $LVS_NOSORTHEADER, $LVS_REPORT))
    _GUICtrlListView_SetExtendedListViewStyle($idListview, $iStylesEx)
    GUISetState(@SW_SHOW)

    ; Charge des images
    $hImage = _GUIImageList_Create(11, 11)
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap(GUICtrlGetHandle($idListview), 0xFF0000, 11, 11))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap(GUICtrlGetHandle($idListview), 0x00FF00, 11, 11))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap(GUICtrlGetHandle($idListview), 0x0000FF, 11, 11))
    _GUICtrlListView_SetImageList($idListview, $hImage, 1)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($idListview, "Items", 120)

    ; Ajoute des éléments
    _GUICtrlListView_AddItem($idListview, "Item 1", 0)
    _GUICtrlListView_AddItem($idListview, "Item 2", 1)
    _GUICtrlListView_AddItem($idListview, "Item 3", 2)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example