UDF > GUI > GuiListView >


_GUICtrlListView_AddItem

Ajoute un nouvel élément à la fin de la liste

#include <GuiListView.au3>
_GUICtrlListView_AddItem ( $hWnd, $sText [, $iImage = -1 [, $iParam = 0]] )

Paramètres

$hWnd ID/handle du contrôle
$sText Texte de l'élément. S'il est défini à -1, l'élément est défini par l'intermédiaire du message de notification $LVN_GETDISPINFO.
$iImage [optionnel] Index, de base 0, de l'icône de l'élément dans la liste d'images du contrôle
$iParam [optionnel] Données définies par l'application

Valeur de retour

Succès: Retourne l'index du nouvel élément.
Échec: Retourne -1

Remarques

Vous ne pouvez pas utiliser cette fonction pour insérer des sous-éléments. Utilisez _GUICtrlListView_AddSubItem() pour insérer des sous-éléments.

Comme AutoIt utilise le paramètre $iParam pour stocker le controlID des éléments ListView créés de façon native, cette valeur doit être suffisamment élevée pour les éléments créés par l'UDF afin d'éviter tout conflit avec des contrôles existants - une valeur de départ de 1000 est recommandée.

En relation

_GUICtrlListView_AddSubItem

Exemple

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>

Example()

Func Example()
    Local $hImage, $idListview

    ; Crée une GUI
    GUICreate("ListView Add Item", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Charge des images
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($idListview, $hImage, 1)

    ; Ajoute des colonnes
    _GUICtrlListView_InsertColumn($idListview, 0, "Column 1", 100)
    _GUICtrlListView_InsertColumn($idListview, 1, "Column 2", 100)
    _GUICtrlListView_InsertColumn($idListview, 2, "Column 3", 100)

    ; Ajoute des éléments
    _GUICtrlListView_AddItem($idListview, "Row 1: Col 1", 0)
    _GUICtrlListView_AddItem($idListview, "Row 2: Col 1", 1)
    _GUICtrlListView_AddItem($idListview, "Row 3: Col 1", 2)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example