UDF > GUI > GuiListView >

_GUICtrlListView_SetGroupInfo

Définit les informations d'un groupe

#include <GuiListView.au3>
_GUICtrlListView_SetGroupInfo ( $hWnd, $iGroupID, $sHeader [, $iAlign = 0 [, $iState = $LVGS_NORMAL]] )

Paramètres

$hWnd ID/handle du contrôle
$iGroupID ID du groupe
$sHeader Texte de l'en-tête
$iAlign [optionnel] L'alignement du texte d'en-tête pour le groupe:
    0 - A gauche
    1 - Au centre
    2 - A droite
$iState [optionnel] Windows Vista ou une version ultérieure peut avoir l'une des valeurs suivantes:
    $LVGS_NORMAL - Les groupes sont développés, le nom du groupe est affiché, et tous les éléments du groupe sont affichés.
    $LVGS_COLLAPSED - Le groupe est développé.
    $LVGS_HIDDEN - Le groupe est caché.
    $LVGS_NOHEADER - Le groupe n'affiche pas un en-tête.
    $LVGS_COLLAPSIBLE - Le groupe peut être développé.
    $LVGS_FOCUSED - Le groupe a le focus clavier.
    $LVGS_SELECTED - Le groupe est sélectionné.
    $LVGS_SUBSETED - Le groupe affiche uniquement une partie de ses éléments.
    $LVGS_SUBSETLINKFOCUSED - Le lien de sous-ensemble du groupe a le focus clavier

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUICtrlListView_GetGroupInfo, _GUICtrlListView_GetGroupInfoByIndex

Exemple

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $aInfo, $hImage, $idListview

    GUICreate("ListView Set Group Info", 400, 300)

    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Charge les images
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($idListview, $hImage, 1)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($idListview, "Column 1", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 2", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 3", 100)

    ; Ajoute des éléments
    _GUICtrlListView_AddItem($idListview, "Row 1: Col 1", 0)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 2", 1)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 3", 2)
    _GUICtrlListView_AddItem($idListview, "Row 2: Col 1", 1)
    _GUICtrlListView_AddSubItem($idListview, 1, "Row 2: Col 2", 1)
    _GUICtrlListView_AddItem($idListview, "Row 3: Col 1", 2)

    ; Construit des groupes
    _GUICtrlListView_EnableGroupView($idListview)
    _GUICtrlListView_InsertGroup($idListview, -1, 1, "Group 1", 1)
    _GUICtrlListView_InsertGroup($idListview, -1, 2, "Group 2")
    _GUICtrlListView_SetItemGroupID($idListview, 0, 1)
    _GUICtrlListView_SetItemGroupID($idListview, 1, 2)
    _GUICtrlListView_SetItemGroupID($idListview, 2, 2)

    ; Modifie les informations de groupe
    $aInfo = _GUICtrlListView_GetGroupInfo($idListview, 1)
    MsgBox($MB_SYSTEMMODAL, "Information", "Group 1 Text: " & $aInfo[0])
    _GUICtrlListView_SetGroupInfo($idListview, 1, "New Group 1")

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example