UDF > GUI > GuiListView >

_GUICtrlListView_GetItemState

Obtient l'état d'un élément de la ListView

#include <GuiListView.au3>
_GUICtrlListView_GetItemState ( $hWnd, $iIndex, $iMask )

Paramètres

$hWnd ID/handle du contrôle
$iIndex Index de l'élément, de base 0
$iMask Les informations d'état à récupérer. Il peut s'agir d'une combinaison de:
    $LVIS_CUT - L'élément est marqué pour une opération couper-coller
    $LVIS_DROPHILITED - L'élément est surligné comme cible d'une opération glisser-déposer
    $LVIS_FOCUSED - L'élément a le focus, il est entouré d'un rectangle de focus standard
    $LVIS_SELECTED - L'élément est sélectionné
    $LVIS_OVERLAYMASK - Utilisez ce masque pour récupérer l'index de l'image de superposition de l'élément
    $LVIS_STATEIMAGEMASK - Utilisez ce masque pour récupérer l'index de l'image d'état de l'élément

Valeur de retour

Retourne l'état actuel de l'élément spécifié.

Remarque

Une information d'état d'un élément comprend un ensemble de flags de bits ainsi que des index de la liste d'images qui indiquent l'image de l'état de l'élément et l'image de superposition

En relation

_GUICtrlListView_SetItemState

Exemple

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hImage, $idListview

    GUICreate("ListView Get Item State", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    _GUICtrlListView_SetExtendedListViewStyle($idListview, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES))
    GUISetState(@SW_SHOW)

    ; Charge les images
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($idListview, $hImage, 1)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($idListview, "Column 1", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 2", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 3", 100)

    ; Ajoute des éléments
    _GUICtrlListView_AddItem($idListview, "Row 1: Col 1", 0)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 2", 1, 1)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 3", 2, 2)
    _GUICtrlListView_AddItem($idListview, "Row 2: Col 1", 1)
    _GUICtrlListView_AddSubItem($idListview, 1, "Row 2: Col 2", 1, 2)
    _GUICtrlListView_AddItem($idListview, "Row 3: Col 1", 2)

    ; Obtient l'état de l'élément 1
    _GUICtrlListView_SetItemState($idListview, 0, $LVIS_FOCUSED, $LVIS_FOCUSED)
    MsgBox($MB_SYSTEMMODAL, "Information", "Item 1 State: " & _GUICtrlListView_GetItemState($idListview, 0, $LVIS_FOCUSED))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example