UDF > GUI > GuiListView >

_GUICtrlListView_GetGroupRect

Obtient le rectangle pour un groupe donné

#include <GuiListView.au3>
_GUICtrlListView_GetGroupRect ( $hWnd, $iGroupID [, $iGet = $LVGGR_GROUP] )

Paramètres

$hWnd ID/handle du contrôle
$iGroupID ID qui spécifie le groupe dont les informations sont à récupérer
$iGet [optionnel] Flag pour préciser les coordonnées du rectangle à obtenir, peut prendre l'une des valeurs suivantes:
    $LVGGR_GROUP - Coordonnées de groupe entier développé
    $LVGGR_HEADER - Coordonnées de l'en-tête uniquement (groupe développé)
    $LVGGR_LABEL - Coordonnées de l'étiquette seulement
    $LVGGR_SUBSETLINK - Coordonnées du lien du sous-ensemble seulement (balisage sous-ensemble)

Valeur de retour

Retourne un tableau avec le format suivant:
    [0] - Coordonnée x du coin supérieur gauche du rectangle
    [1] - Coordonnée y du coin supérieur gauche du rectangle
    [2] - Coordonnée x du coin inférieur droit du rectangle
    [3] - Coordonnée y du coin inférieur droit du rectangle

Remarque

Windows Vista ou une version ultérieure

Exemple

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $aInfo, $hImage, $idListview

    GUICreate("ListView Get Group Info", 400, 300)

    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Charge les images
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListview), 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListview), 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListview), 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($idListview, $hImage, 1)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($idListview, "Column 1", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 2", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 3", 100)

    ; Ajoute des éléments
    _GUICtrlListView_AddItem($idListview, "Row 1: Col 1", 0)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 2", 1)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 3", 2)
    _GUICtrlListView_AddItem($idListview, "Row 2: Col 1", 1)
    _GUICtrlListView_AddSubItem($idListview, 1, "Row 2: Col 2", 1)
    _GUICtrlListView_AddItem($idListview, "Row 3: Col 1", 2)

    ; Construit des groupes
    _GUICtrlListView_EnableGroupView($idListview)
    _GUICtrlListView_InsertGroup($idListview, -1, 1, "Group 1", 1)
    _GUICtrlListView_InsertGroup($idListview, -1, 2, "Group 2")
    _GUICtrlListView_SetItemGroupID($idListview, 0, 1)
    _GUICtrlListView_SetItemGroupID($idListview, 1, 2)
    _GUICtrlListView_SetItemGroupID($idListview, 2, 2)

    ; Obtient le rectangle du Groupe d'ID 2
    $aInfo = _GUICtrlListView_GetGroupRect($idListview, 2)
    MsgBox($MB_SYSTEMMODAL, "Information", "Rect: " & @CRLF & _
            @TAB & "Left..: " & $aInfo[0] & @CRLF & _
            @TAB & "Top...: " & $aInfo[1] & @CRLF & _
            @TAB & "Right.: " & $aInfo[2] & @CRLF & _
            @TAB & "Bottom: " & $aInfo[3])

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example