UDF > GUI > GuiListView >


_GUICtrlListView_DeleteItem

Supprime un élément d'un contrôle ListView

#include <GuiListView.au3>
_GUICtrlListView_DeleteItem ( $hWnd, $iIndex )

Paramètres

$hWnd ID/handle du contrôle
$iIndex Index, de base 0, de l'élément à supprimer

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUICtrlListView_DeleteAllItems, _GUICtrlListView_DeleteItemsSelected

Exemples

Exemple 1

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    GUICreate("ListView Item Deletion", 400, 500)
    Local $idListview = GUICtrlCreateListView("Col 1               |Col 2      |Col 3      ", 10, 10, 380, 480, $LVS_SHOWSELALWAYS)
    GUISetState(@SW_SHOW)

    For $i = 0 To 9
        GUICtrlCreateListViewItem("Native Item " & $i & "|Item " & $i & "-1|Item " & $i & "-2", $idListview)
    Next
    For $i = 10 To 20
        _GUICtrlListView_AddItem($idListview, "UDF Item " & $i, -1, 1000 + $i)
        _GUICtrlListView_AddSubItem($idListview, $i, "Item " & $i & "-1", 1)
        _GUICtrlListView_AddSubItem($idListview, $i, "Item " & $i & "-2", 2)
    Next

    ; Passe le controlID d'une ListView créée de façon native pour supprimer à la fois les
    ; éléments créés de façon native et les éléments créés avec l'UDF
    MsgBox($MB_SYSTEMMODAL, "Delete item", "Deleting UDF-created Item 12")
    _GUICtrlListView_DeleteItem($idListview, 12)

    MsgBox($MB_SYSTEMMODAL, "Single", "Deleting native-created Item 5")
    _GUICtrlListView_DeleteItem($idListview, 5)

    ; Boucle jusqu'à ce que l'utilisateur quitte
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Supprime la GUI et tous les contrôles.
    GUIDelete()
EndFunc   ;==>Example


Exemple 2

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example_UDF_Created()

Func Example_UDF_Created()
    Local $aItems[10][3]

    Local $hGUI = GUICreate("(UDF Created) ListView Delete All Items", 400, 300)
    Local $hListView = _GUICtrlListView_Create($hGUI, "col1|col2|col3", 10, 10, 380, 280)
    GUISetState(@SW_SHOW)

    ; Charge 3 colonnes
    For $i = 0 To UBound($aItems) - 1
        $aItems[$i][0] = "Item " & $i
        $aItems[$i][1] = "Item " & $i & "-1"
        $aItems[$i][2] = "Item " & $i & "-2"
    Next

    _GUICtrlListView_AddArray($hListView, $aItems)

    MsgBox($MB_SYSTEMMODAL, "Delete item", "Deleting Item 7")
    ; Passe le handle d'une ListView créée de façon native
    _GUICtrlListView_DeleteItem($hListView, 7)

    ; Boucle jusqu'à ce que l'utilisateur quitte
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Supprime la GUI et tous les contrôles.
    GUIDelete()
EndFunc   ;==>Example_UDF_Created