Functions > GUI > GUICtrlCreate >


GUICtrlCreateListViewItem

Crée un contrôle -ListViewItem- représentant un élément d'une ListView.

GUICtrlCreateListViewItem ( "text", listviewID )

Paramètres

text Texte des sous-éléments séparés avec Opt("GUIDataSeparatorChar") .
listviewID ControlID du contrôle ListView auquel l'élément appartient.

Valeur de retour

Succès: Retourne l'identifiant ( controlID ) du nouveau contrôle.
Échec: Retourne 0.

Remarques

Cette fonction crée un élément d'une ListView qui peut ensuite être sélectionnés. Les éléments fonctionnent comme des contrôles normaux et peuvent être définis avec GUICtrlSetData() .
Les élémens peuvent être supprimés comme n'importe quel autre contrôle à l'aide GUICtrlDelete() .
Les éléments d'une ListView peuvent être glissés/déposés dans un contrôle Edit ou Input avec l'état ​​$GUI_DROPACCEPTED.
Consultez GUICtrlCreateListView() sur le redimensionnement de la colonne.

Le flag spécial $GUI_BKCOLOR_LV_ALTERNATE peut être utilisé avec le contrôle ListView pour donner une couleur de fond alternative suivant les lignes de ListviewItems.
Les lignes impaires auront la couleur définie par GUICtrlSetBkColor() du contrôle ListView.
Les lignes paires auront la couleur définie par GUICtrlSetBkColor() du contrôle ListViewItem.

Les constantes ci-dessus sont définies dans #include <GUIConstantsEx.au3>

En relation

GUICtrlCreateListView, GUICtrlDelete, GUICtrlRead, GUICtrlSetData, GUICtrlSetState, GUIDataSeparatorChar (Option), GUIGetMsg

Exemple

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    GUICreate("listview items", 220, 250, 100, 200, -1, $WS_EX_ACCEPTFILES)
    GUISetBkColor(0x00E0FFFF)  ; Change la couleur de fond

    Local $idListview = GUICtrlCreateListView("col1  |col2|col3  ", 10, 10, 200, 150) ;, $LVS_SORTDESCENDING)
    Local $idButton = GUICtrlCreateButton("Value?", 75, 170, 70, 20)
    Local $idItem1 = GUICtrlCreateListViewItem("item2|col22|col23", $idListview)
    Local $idItem2 = GUICtrlCreateListViewItem("item1|col12|col13", $idListview)
    Local $idItem3 = GUICtrlCreateListViewItem("item3|col32|col33", $idListview)
    GUICtrlCreateInput("", 20, 200, 150)
    GUICtrlSetState(-1, $GUI_DROPACCEPTED)  ; pour permettre de glisser-déposer
    GUISetState(@SW_SHOW)
    GUICtrlSetData($idItem2, "ITEM1")
    GUICtrlSetData($idItem3, "||COL33")
    GUICtrlDelete($idItem1)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Local $idMsg = GUIGetMsg() 
    While $idMsg <> $GUI_EVENT_CLOSE
        Switch 
            Case $idButton
                MsgBox($MB_SYSTEMMODAL, "listview item", GUICtrlRead(GUICtrlRead($idListview)), 2)

            Case $idListview
                MsgBox($MB_SYSTEMMODAL, "listview", "clicked=" & GUICtrlGetState($idListview), 2)

        EndSwitch
        $idMsg = GUIGetMsg()
    WEnd
EndFunc   ;==>Example