UDF > GUI > GuiListView >


_GUICtrlListView_AddArray

Ajoute les éléments d'un tableau au contrôle ListView

#include <GuiListView.au3>
_GUICtrlListView_AddArray ( $hWnd, ByRef $aItems )

Paramètres

$hWnd ID/handle du contrôle
$aItems Tableau avec le format suivant:
    [0][0] - Élément 1 Texte
    [0][1] - Élément 1 Sous-élément 1 Texte
    [0][2] - Élément 1 Sous-élément 2 Texte
    [0][n] - Élément 1 Sous-élément n Texte
    [1][0] - Élément 2 Texte
    [1][1] - Élément 2 Sous-élément 1 Texte
    [1][2] - Élément 2 Sous-élément 2 Texte
    [1][n] - Élément 2 Sous-élément n Texte

Valeur de retour

Aucune.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $iI, $iTimer, $idListview

    ; Crée une GUI
    GUICreate("ListView Add Array", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($idListview, "Items", 100)
    _GUICtrlListView_AddColumn($idListview, "SubItems 1", 100)
    _GUICtrlListView_AddColumn($idListview, "SubItems 2", 100)
    _GUICtrlListView_AddColumn($idListview, "SubItems 3", 100)

    _GUICtrlListView_SetItemCount($idListview, 5000)

    ; Remplit la colonne 1
    Local $aItems[5000][1]
    For $iI = 0 To UBound($aItems) - 1
        $aItems[$iI][0] = "Item " & $iI
    Next
    $iTimer = TimerInit()
    _GUICtrlListView_AddArray($idListview, $aItems)
    MsgBox($MB_SYSTEMMODAL, "Information", "Load time: " & TimerDiff($iTimer) / 1000 & " seconds")

    _GUICtrlListView_DeleteAllItems(GUICtrlGetHandle($idListview)) ; éléments ajoutés avec la fonction UDF peuvent être supprimés en utilisant la fonction UDF

    ; Remplit la colonne 4
    Local $aItems[5000][4]
    For $iI = 0 To UBound($aItems) - 1
        $aItems[$iI][0] = "Item " & $iI
        $aItems[$iI][1] = "Item " & $iI & "-1"
        $aItems[$iI][2] = "Item " & $iI & "-2"
        $aItems[$iI][3] = "Item " & $iI & "-3"
    Next
    $iTimer = TimerInit()
    _GUICtrlListView_AddArray($idListview, $aItems)
    MsgBox($MB_SYSTEMMODAL, "Information", "Load time: " & TimerDiff($iTimer) / 1000 & " seconds")

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example