UDF > GUI > GuiListView >

_GUICtrlListView_DeleteAllItems

Supprime tous les éléments d'un contrôle ListView

#include <GuiListView.au3>
_GUICtrlListView_DeleteAllItems ( $hWnd )

Paramètre

$hWnd ID/handle du contrôle

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarque

Supprimer tous les éléments d'un ListView créé de façon native peut prendre du temps - il est recommandé d'enfermer cette commande dans une paire _GUICtrlListView_Begin/EndUpdate si c'est le cas.

En relation

_GUICtrlListView_DeleteItem, _GUICtrlListView_DeleteItemsSelected

Exemples

Exemple 1

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    GUICreate("ListView Item Deletion", 400, 500)
    Local $idListview = GUICtrlCreateListView("Col 1               |Col 2      |Col 3      ", 10, 10, 380, 480, $LVS_SHOWSELALWAYS)

    ; Affiche la GUI.
    GUISetState(@SW_SHOW)

    For $i = 0 To 9
        GUICtrlCreateListViewItem("Native Item " & $i & "|Item " & $i & "-1|Item " & $i & "-2", $idListview)
    Next
    For $i = 10 To 20
        _GUICtrlListView_AddItem($idListview, "UDF Item " & $i, -1, 1000 + $i)
        _GUICtrlListView_AddSubItem($idListview, $i, "Item " & $i & "-1", 1)
        _GUICtrlListView_AddSubItem($idListview, $i, "Item " & $i & "-2", 2)
    Next

    MsgBox($MB_SYSTEMMODAL, "Delete all", "Deleting both native and UDF Items")

    ; Passe le handle de la ListView créée par l'UDF
    _GUICtrlListView_DeleteAllItems($idListview)

    ; Boucle jusqu'à ce que l'utilisateur quitte
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    
    ; Supprime la GUI et tous les contrôles.
    GUIDelete()
EndFunc   ;==>Example

Exemple 2

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example() ; Un contrôle ListView créé avec l'UDF.

Func Example()
    Local $aItems[10][3]

    Local $hGUI = GUICreate("(UDF Created) ListView Delete All Items", 400, 300)
    Local $hListView = _GUICtrlListView_Create($hGUI, "col1|col2|col3", 10, 10, 380, 280)

    ; Affiche la GUI.
    GUISetState(@SW_SHOW)

    ; Charge 3 colonnes
    For $i = 0 To UBound($aItems) - 1
        $aItems[$i][0] = "Item " & $i
        $aItems[$i][1] = "Item " & $i & "-1"
        $aItems[$i][2] = "Item " & $i & "-2"
    Next

    _GUICtrlListView_AddArray($hListView, $aItems)

    MsgBox($MB_SYSTEMMODAL, "Delete all", "Delete all items")

    ; Passe le handle de la ListView créée avec l'UDF
    _GUICtrlListView_DeleteAllItems($hListView)

    ; Boucle jusqu'à ce que l'utilisateur quitte
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Supprime la GUI et tous les contrôles.
    GUIDelete()
EndFunc   ;==>Example