Functions > VarConv >


UBound

Retourne la taille des dimensions d'un tableau ou le nombre de clés d'une table.

UBound ( Variable [, Dimension = 1] )

Paramètres

Variable La variable tableau ou table à examiner.
Dimension [optionnel] Pour un tableau multi-dimensionnel, la dimension dont il faut retourner la taille:
    $UBOUND_DIMENSIONS (0) = Nombre de dimensions du tableau
    $UBOUND_ROWS (1) = Nombre de rangées du tableau (par défaut)
    $UBOUND_COLUMNS (2) = Nombre de colonnes du tableau
Pour un Array de plus de deux dimensions, utilisez l'entier correspondant à la dimension.
Pour un Map - ce paramètre est ignoré et le nombre de clés est retourné.

Les constantes sont définies dans "AutoItConstants.au3".

Valeur de retour

Succès: Retourne la taille d'une dimension d'un Array ou le nombre de clés d'une Map.
Échec: Retourne 0 et définit @error <> 0.
@error: 1 = Le paramètre Variable n'est pas un tableau (Array), ni une table (Map).
2 = La dimension du tableau est invalide.

Remarque

Rappelez-vous que pour les tableaux, la valeur retournée est supérieur de 1 à l'index du dernier élément dans la dimension, puisque les index sont comptés à partir de 0.

En relation

Global/Local, ReDim, IsArray

Exemple

#include <AutoItConstants.au3>
#include <MsgBoxConstants.au3>
#include <Array.au3> ; Nécessaire pour _ArrayDisplay.

Example()

Func Example()
    Local $aArray[10][20]
    Local $iRows = UBound($aArray, $UBOUND_ROWS) ; Nombre total de lignes. Dans cet exemple, ce sera 10.
    Local $iCols = UBound($aArray, $UBOUND_COLUMNS) ; Nombre total de colonnes. Dans cet exemple, ce sera 20.
    Local $iDimension = UBound($aArray, $UBOUND_DIMENSIONS) ; Le nombre de dimensions tableau, ici 2.

    MsgBox($MB_SYSTEMMODAL, "", "Le tableau a " & $iDimension & " dimension(s) " & _
            $iRows & " rangée(s) & " & $iCols & " colonne(s).")

    ; Remplit le tableau avec les données.
    For $i = 0 To $iRows - 1
        For $j = 0 To $iCols - 1
            $aArray[$i][$j] = "Row: " & $i & " - Col: " & $j
        Next
    Next
    _ArrayDisplay($aArray)
EndFunc   ;==>Example