UDF > GUI > GuiEdit >

_GUICtrlEdit_LineIndex

Obtient l'index du premier caractère de la ligne spécifiée

#include <GuiEdit.au3>
_GUICtrlEdit_LineIndex ( $hWnd [, $iIndex = -1] )

Paramètres

$hWnd ID/handle du contrôle
$iIndex [optionnel] Spécifie le numéro, à partir de 0, de la ligne

Valeur de retour

Succès: Retourne l'index du premier caractère de la ligne spécifiée dans le paramètre $iIndex.
Échec: Retourne 1 si le numéro de ligne spécifié est supérieur au nombre de lignes du contrôle d'édition.

Remarque

$iIndex = -1 indique le numéro de la ligne courante (la ligne qui contient le curseur).

Exemple

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hStatusBar, $idEdit, $hGUI
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"
    Local $aPartRightSide[2] = [378, -1], $iRandom

    ; Crée une GUI
    $hGUI = GUICreate("Edit Line Index", 400, 300)
    $idEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
    _GUICtrlStatusBar_SetIcon($hStatusBar, 1, 97, "shell32.dll")
    GUISetState(@SW_SHOW)

    ; Définit les marges
    _GUICtrlEdit_SetMargins($idEdit, BitOR($EC_LEFTMARGIN, $EC_RIGHTMARGIN), 10, 10)

    ; Définit le texte
    _GUICtrlEdit_SetText($idEdit, FileRead($sFile))

    ; Index de la ligne
    $iRandom = Random(0, _GUICtrlEdit_GetLineCount($idEdit) - 1, 1)
    _GUICtrlStatusBar_SetText($hStatusBar, "Char Index: " & _GUICtrlEdit_LineIndex($idEdit, $iRandom) & " from Line: " & $iRandom)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example