UDF > Clipboard >

_ClipBoard_Open

Ouvre le presse-papiers et empêche d'autres applications de modifier le presse-papiers

#include <Clipboard.au3>
_ClipBoard_Open ( $hOwner )

Paramètre

$hOwner Handle de la fenêtre qui est associée au presse-papiers ouvert. Si ce paramètre vaut 0, le presse-papiers ouvert est associé à la tâche en cours.

Valeur de retour

Succès: Retourne True
Échec: Retourne False

Remarque

Cette fonction échoue si une autre fenêtre a le presse-papiers ouvert. Appelez la fonction _ClipBoard_Close() après chaque appel réussi à cette fonction.
La fenêtre identifiée par le paramètre $hOwner ne devient pas le propriétaire du presse-papiers à moins que la fonction _ClipBoard_Empty() soit appelée. Si vous appelez _ClipBoard_Open() avec hwnd défini à 0, _ClipBoard_Empty() définit le propriétaire du presse-papiers à 0 ce qui provoque l'échec de _ClipBoard_SetData().

En relation

_ClipBoard_Close, _ClipBoard_Empty, _ClipBoard_EnumFormats, _ClipBoard_GetOpenWindow, _ClipBoard_SetDataEx

Voir aussi

Consultez OpenClipboard dans la Librairie MSDN.

Exemple

#include <Clipboard.au3>
#include <GUIConstantsEx.au3>
#include <WinAPIError.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI

    ; Crée une GUI
    $hGUI = GUICreate("Clipboard", 600, 400)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ouvre le presse-papiers
    If _ClipBoard_Open($hGUI) Then

        ShowData($hGUI)

        ; Ferme le presse-papiers
        _ClipBoard_Close()
    Else
        _WinAPI_ShowError("_ClipBoard_Open failed")
    EndIf

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Affiche les statistiques du presse-papiers
Func ShowData($hGUI)
    MemoWrite("GUI handle ............: " & $hGUI)
    MemoWrite("Clipboard owner .......: " & _ClipBoard_GetOwner())
    MemoWrite("Clipboard open window .: " & _ClipBoard_GetOpenWindow())
    MemoWrite("Clipboard sequence ....: " & _ClipBoard_GetSequenceNumber())
    MemoWrite()
EndFunc   ;==>ShowData

; Ecrit un message dans Memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite