UDF > Clipboard >

_ClipBoard_GetOwner

Obtient le handle de la fenêtre du propriétaire actuel du presse-papiers

#include <Clipboard.au3>
_ClipBoard_GetOwner ( )

Valeur de retour

Succès: Retourne le handle de la fenêtre du propriétaire actuel du presse-papiers
Échec: Retourne 0

Remarque

Le presse-papiers peut encore contenir des données même si le presse-papiers n'est pas actuellement propriétaire d'une fenêtre. En général, le propriétaire du presse-papiers est la fenêtre qui a placé en dernier des données dans le presse-papiers.
La fonction _ClipBoard_Empty() assigne la propriété du presse-papiers.

En relation

_ClipBoard_Empty, _ClipBoard_GetOpenWindow

Voir aussi

Consultez GetClipboardOwner dans la Librairie MSDN.

Exemple

#include <Clipboard.au3>
#include <GUIConstantsEx.au3>
#include <WinAPIError.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI

    ; Crée une GUI
    $hGUI = GUICreate("Clipboard", 600, 400)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ouvre le presse-papiers
    If _ClipBoard_Open($hGUI) Then

        ShowData($hGUI)

        ; Ferme le presse-papiers
        _ClipBoard_Close()
    Else
        _WinAPI_ShowError("_ClipBoard_Open failed")
    EndIf

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Affiche les statistiques du presse-papiers
Func ShowData($hGUI)
    MemoWrite("GUI handle ............: " & $hGUI)
    MemoWrite("Clipboard owner .......: " & _ClipBoard_GetOwner())
    MemoWrite("Clipboard open window .: " & _ClipBoard_GetOpenWindow())
    MemoWrite("Clipboard sequence ....: " & _ClipBoard_GetSequenceNumber())
    MemoWrite()
EndFunc   ;==>ShowData

; Ecrit un message dans Memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite