UDF > Clipboard >

_ClipBoard_EnumFormats

Énumère les formats de données actuellement disponibles dans le presse-papiers

#include <Clipboard.au3>
_ClipBoard_EnumFormats ( $iFormat )

Paramètre

$iFormat Indique un format de presse-papiers qui est connu pour être disponible. Pour commencer une énumération de formats, définir $iFormat à zéro.
Lorsque $iFormat est nul, la fonction récupère le premier format disponible du presse-papiers.
Pour les appels suivants au cours d'une énumération, définir $iFormat avec le résultat de l'appel précédent.

Valeur de retour

Succès: Retourne le format du presse-papiers qui suit le format spécifié
Échec: Retourne 0

Remarque

Vous devez ouvrir le presse-papiers avant d'énumérer ses formats.

En relation

_ClipBoard_CountFormats, _ClipBoard_GetPriorityFormat, _ClipBoard_Open, _ClipBoard_RegisterFormat

Voir aussi

Consultez EnumClipboardFormats dans la Librairie MSDN.

Exemple

#include <Clipboard.au3>
#include <GUIConstantsEx.au3>
#include <WinAPIError.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $iFormat, $iCount

    ; Crée une GUI
    $hGUI = GUICreate("Clipboard", 600, 400)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ouvre le presse-papiers
    If _ClipBoard_Open($hGUI) Then

        ; Affiche les formats disponibles du presse-papiers
        MemoWrite("Clipboard formats ..: " & _ClipBoard_CountFormats())

        ; Énumére les formats du presse-papiers
        Do
            $iFormat = _ClipBoard_EnumFormats($iFormat)
            If $iFormat <> 0 Then
                $iCount += 1
                MemoWrite("Clipboard format " & $iCount & " .: " & _ClipBoard_FormatStr($iFormat))
            EndIf
        Until $iFormat = 0

        ; Ferme le presse-papiers
        _ClipBoard_Close()
    Else
        _WinAPI_ShowError("_ClipBoard_Open failed")
    EndIf

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit un message dans mémo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite