UDF > Clipboard >

_ClipBoard_GetSequenceNumber

Récupère le numéro de séquence du presse-papiers pour la station de fenêtre actuelle

#include <Clipboard.au3>
_ClipBoard_GetSequenceNumber ( )

Valeur de retour

Succès: Retourne le numéro de séquence du presse-papiers
Échec: Retourne 0

Remarque

Le système conserve un numéro de série pour le presse-papiers pour chaque station de fenêtre. Ce nombre est incrémenté lorsque le contenu du presse-papiers change ou le presse-papiers est vidé. Vous pouvez suivre cette valeur pour déterminer si le contenu du presse-papiers a changé et optimiser la création d'objets de données. Si l'actualisation du presse-papiers est retardée, le numéro de séquence n'est pas incrémenté jusqu'à ce que les changements soient actualisés.

Voir aussi

Consultez GetClipboardSequenceNumber dans la Librairie MSDN.

Exemple

#include <Clipboard.au3>
#include <GUIConstantsEx.au3>
#include <WinAPIError.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI

    ; Crée une GUI
    $hGUI = GUICreate("Clipboard", 600, 400)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ouvre le presse-papiers
    If _ClipBoard_Open($hGUI) Then

        ShowData($hGUI)

        ; Ferme le presse-papiers
        _ClipBoard_Close()
    Else
        _WinAPI_ShowError("_ClipBoard_Open failed")
    EndIf

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Affiche les statistiques du presse-papiers
Func ShowData($hGUI)
    MemoWrite("GUI handle ............: " & $hGUI)
    MemoWrite("Clipboard owner .......: " & _ClipBoard_GetOwner())
    MemoWrite("Clipboard open window .: " & _ClipBoard_GetOpenWindow())
    MemoWrite("Clipboard sequence ....: " & _ClipBoard_GetSequenceNumber())
    MemoWrite()
EndFunc   ;==>ShowData

; Ecrit un message dans Memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite