UDF > Clipboard >

_ClipBoard_GetOpenWindow

Récupère le handle de la fenêtre qui a actuellement le presse-papiers ouvert

#include <Clipboard.au3>
_ClipBoard_GetOpenWindow ( )

Valeur de retour

Succès: Retourne le handle de la fenêtre qui a le presse-papiers ouvert
Échec: Retourne 0 si aucune fenêtre n'a le presse-papiers ouvert

Remarque

Si une application ou DLL spécifie un handle de fenêtre NULL lors de l'appel de la fonction _ClipBoard_Open(), le presse-papiers est ouvert mais n'est pas associé à une fenêtre. Dans ce cas, _ClipBoard_GetOpenWindow() retourne 0.

En relation

_ClipBoard_GetOwner, _ClipBoard_Open

Voir aussi

Consultez GetOpenClipboardWindow dans la Librairie MSDN.

Exemple

#include <Clipboard.au3>
#include <GUIConstantsEx.au3>
#include <WinAPIError.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI

    ; Crée une GUI
    $hGUI = GUICreate("Clipboard", 600, 400)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ouvre le presse-papiers
    If _ClipBoard_Open($hGUI) Then

        ShowData($hGUI)

        ; Ferme le presse-papiers
        _ClipBoard_Close()
    Else
        _WinAPI_ShowError("_ClipBoard_Open failed")
    EndIf

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Affiche les statistiques du presse-papiers
Func ShowData($hGUI)
    MemoWrite("GUI handle ............: " & $hGUI)
    MemoWrite("Clipboard owner .......: " & _ClipBoard_GetOwner())
    MemoWrite("Clipboard open window .: " & _ClipBoard_GetOpenWindow())
    MemoWrite("Clipboard sequence ....: " & _ClipBoard_GetSequenceNumber())
    MemoWrite()
EndFunc   ;==>ShowData

; Ecrit un message dans Memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite