UDF > GUI > GuiToolTip >

_GUIToolTip_SetDelayTime

Définit les durées Initial, Popup et Reshow d'un contrôle info-bulle

#include <GuiToolTip.au3>
_GUIToolTip_SetDelayTime ( $hWnd, $iDuration, $iTime )

Paramètres

$hWnd Handle du contrôle info-bulle (retourné par _GUIToolTip_Create.)
$iDuration Flag qui spécifie quelle durée sera fixée:
    $TTDT_AUTOMATIC (0) - Définit les trois délais par défaut proportionnellement. (voir Remarques)
    $TTDT_RESHOW (1) = Temps nécessaire pour qu'une fenêtre info-bulle apparaîsse lorsque le pointeur se déplace d'un élément à un autre
    $TTDT_AUTOPOP (2) = Temps pendant lequel la fenêtre info-bulle reste visible si le pointeur est à l'arrêt dans le rectangle de délimitation d'un élément déclencheur
    $TTDT_INITIAL (3) = Temps pendant lequel le pointeur doit rester immobile dans le rectangle de délimitation d'un élément déclencheur avant que la fenêtre s'affiche

Les constantes sont définies dans ToolTipConstants.au3
$iTime Délai en millisecondes
Les constantes sont définies dans ToolTipConstants.au3

Valeur de retour

Aucune.

Remarques

Les délais par défaut sont basés sur la durée du double-clic. Le délai Autopop sera dix fois le délai Initial et le délai Reshow sera un cinquième du délai Initial.
Pour la durée du double-click de 500 ms, les délais Initial, Autopop, et Reshow sont 500ms, 5000ms et 100ms respectivement.

Si le flag $iDuration est défini sur $TTDT_AUTOMATIC, utilisez une valeur positive de $iTime pour spécifier le délai Initial, en millisecondes. Réglez $iTime à une valeur négative pour réinitialiser les trois délais à leurs valeurs par défaut.

En relation

_GUIToolTip_GetDelayTime

Exemple

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGUI = GUICreate(StringTrimRight(@ScriptName, StringLen(".exe")), 350, 200)

    Local $idButton = GUICtrlCreateButton("Button ToolTip", 30, 32, 130, 28)
    Local $hButton = GUICtrlGetHandle($idButton)
    ; Crée un contrôle info-bulle
    Local $hToolTip = _GUIToolTip_Create($hGUI)

    ; Ajoute un élément au contrôle info-bulle
    _GUIToolTip_AddTool($hToolTip, 0, "This is the ToolTip text", $hButton)

    ; Définit le temps pendant lequel l'info-bulle reste affichée à 1500 ms
    _GUIToolTip_SetDelayTime($hToolTip, $TTDT_AUTOPOP, 1500)
    GUISetState(@SW_SHOW)
    ; Obtient et affiche la durée d'affichage de l'info-bulle
    MsgBox($MB_SYSTEMMODAL, 'Message', 'Display time : ' & _GUIToolTip_GetDelayTime($hToolTip, $TTDT_AUTOPOP) & ' ms')

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
   
    ; Détruit le contrôle info-bulle
    _GUIToolTip_Destroy($hToolTip)
    GUIDelete($hGUI)
EndFunc   ;==>Example