UDF > GUI > GuiToolTip >

_GUIToolTip_GetDelayTime

Obtient les durées Initial, Popup ou Reshow d'un contrôle info-bulle

#include <GuiToolTip.au3>
_GUIToolTip_GetDelayTime ( $hWnd, $iDuration )

Paramètres

$hWnd Handle du contrôle info-bulle (retourné par _GUIToolTip_Create.)
$iDuration Flag qui spécifie quelle durée il faut récupérer:
    $TTDT_RESHOW (1) = Temps nécessaire pour qu'une fenêtre info-bulle apparaîsse lorsque le pointeur se déplace d'un élément à un autre
    $TTDT_AUTOPOP (2) = Temps pendant lequel la fenêtre info-bulle reste visible si le pointeur est à l'arrêt dans le rectangle de délimitation d'un élément déclencheur
    $TTDT_INITIAL (3) = Temps pendant lequel le pointeur doit rester immobile dans le rectangle de délimitation d'un élément déclencheur avant que la fenêtre s'affiche

Les constantes sont définies dans ToolTipConstants.au3

Valeur de retour

Retourne la durée spécifiée en millisecondes.

En relation

_GUIToolTip_SetDelayTime

Exemple

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGUI = GUICreate(StringTrimRight(@ScriptName, StringLen(".exe")), 350, 200)

    Local $idButton = GUICtrlCreateButton("This is a button", 30, 32, 130, 28)
    Local $hButton = GUICtrlGetHandle($idButton)
    ; Crée un contrôle info-bulle
    Local $hToolTip = _GUIToolTip_Create($hGUI)

    ; Ajoute un élément au contrôle info-bulle
    _GUIToolTip_AddTool($hToolTip, 0, "This is the ToolTip text", $hButton)

    ; Définit le temps d'affichage de l'info-bulle, à 1500 ms ($TTDT_AUTOPOP)
    _GUIToolTip_SetDelayTime($hToolTip, $TTDT_AUTOPOP, 1500)
    GUISetState(@SW_SHOW)

    MsgBox($MB_SYSTEMMODAL, 'Message', 'Display time : ' & _GUIToolTip_GetDelayTime($hToolTip, $TTDT_AUTOPOP) & ' ms')

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    _GUIToolTip_Destroy($hToolTip)
    GUIDelete($hGUI)

EndFunc   ;==>Example