UDF > GUI > GuiToolTip >

_GUIToolTip_GetTitleBitMap

Obtient le titre de l'icône bitmap

#include <GuiToolTip.au3>
_GUIToolTip_GetTitleBitMap ( $hWnd )

Paramètre

$hWnd Handle du contrôle info-bulle (retourné par _GUIToolTip_Create.)

Valeur de retour

Retourne le numéro de référence de l'icône du titre de l'info-bulle. Voir Remarque

Remarque

Le numéro de référence de l'icône retournée par cette fonction est liée aux icônes utilisées pour définir l'icône de titre, voir _GUIToolTip_SetTitle().
Si vous utilisez les icônes standards, les valeurs de retour seront:
        $TTI_NONE = 0
        $$TTI_INFO ou TTI_INFO_LARGE = 1
        $$TTI_WARNING ou TTI_WARNING_LARGE = 2
        $$TTI_ERROR ou TTI_ERROR_LARGE = 3
Toute icône utilisée qui n'est pas une de celles-ci retournera la valeur 4, signifiant qu'une HICON a été utilisée.

En relation

_GUIToolTip_SetTitle

Exemple

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIIcons.au3>

Example()

Func Example()
    Local $hGUI = GUICreate(StringTrimRight(@ScriptName, StringLen(".exe")), 350, 200)

    Local $idButton = GUICtrlCreateButton("Button", 30, 32, 130, 28)
    Local $hButton = GUICtrlGetHandle($idButton)

    ; Crée un contrôle info-bulle
    Local $hToolTip = _GUIToolTip_Create($hGUI)

    ; Ajoute un élément au contrôle info-bulle
    _GUIToolTip_AddTool($hToolTip, 0, "This is the ToolTip text", $hButton)

    Local $hIcon = _WinAPI_LoadShell32Icon(15)

    ; Définit le titre de l'info-bulle
    _GUIToolTip_SetTitle($hToolTip, 'This is the Title Text', $hIcon)

    GUISetState(@SW_SHOW)

    Local $iMsg
    Do
        $iMsg = GUIGetMsg()
        if $iMsg = $idButton Then
            MsgBox($MB_SYSTEMMODAL, "Title Bitmap", _GUIToolTip_GetTitleBitMap($hToolTip))
        EndIf
    Until $iMsg = $GUI_EVENT_CLOSE

    ; Détruit le contrôle info-bulle
    _GUIToolTip_Destroy($hToolTip)
    GUIDelete($hGUI)
EndFunc   ;==>Example