UDF > GUI > GuiToolTip >

_GUIToolTip_GetMarginEx

Obtient, dans une structure, les marges gauche, supérieure, droite, et inférieure d'un contrôle info-bulle

#include <GuiToolTip.au3>
_GUIToolTip_GetMarginEx ( $hWnd )

Paramètre

$hWnd Handle du contrôle info-bulle (retourné par _GUIToolTip_Create.)

Valeur de retour

Retourne une structure $tagRECT qui recevra les informations sur les marges:
    Top - Distance entre la bordure supérieure et le haut du texte de l'info-bulle, en pixels
    Left - Distance entre la bordure gauche et extrémité gauche du texte de l'info-bulle, en pixels
    Bottom - Distance entre la bordure inférieure et le bas du texte de l'info-bulle, en pixels
    Right - Distance entre la bordure droite et l'extrémité droite du texte de l'info-bulle, en pixels

En relation

_GUIToolTip_GetMargin, _GUIToolTip_ToolToArray

Exemple

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>
#include <MsgBoxConstants.au3>
#include <WinAPITheme.au3>

Example()

Func Example()
    Local $hGUI = GUICreate(StringTrimRight(@ScriptName, StringLen(".exe")), 350, 200)

    Local $idButton = GUICtrlCreateButton("Button", 30, 32, 130, 28)
    Local $hButton = GUICtrlGetHandle($idButton)
    ; Crée un contrôle info-bulle
    Local $hToolTip = _GUIToolTip_Create($hGUI, BitOR($_TT_ghTTDefaultStyle, $TTS_BALLOON))

    ; Si vous utilisez un paramètre de thème Windows, cela désactive cette option pour l'info-bulle affichée, 
    ; de sorte que vous pouvez modifier les paramètres de marge. Si vous ne le faites pas, les marges n'apparaitront pas différentes    
    _WinAPI_SetWindowTheme($hToolTip, "", "")

    ; Ajoute un élément au contrôle info-bulle
    _GUIToolTip_AddTool($hToolTip, 0, "This is the ToolTip text", $hButton)
    ; Définissez manuellement les marges de l'info-bulle au lieu d'utiliser les paramètres par défaut.
    _GUIToolTip_SetMargin($hToolTip, 30, 10, 20, 12)

    ; Obtient les paramètres de marge de l'info-bulle
    Local $tRECT = _GUIToolTip_GetMarginEx($hToolTip)
    GUISetState(@SW_SHOW)
    MsgBox($MB_SYSTEMMODAL, 'Message', _
            'Left :' & @TAB & DllStructGetData($tRECT, "Left") & @LF & _
            'Top :' & @TAB & DllStructGetData($tRECT, "Top") & @LF & _
            'Right :' & @TAB & DllStructGetData($tRECT, "Right") & @LF & _
            'Bottom :' & @TAB & DllStructGetData($tRECT, "Bottom"))
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Détruit le contrôle info-bulle
    _GUIToolTip_Destroy($hToolTip)
    GUIDelete($hGUI)
EndFunc   ;==>Example