UDF > GUI > GuiToolTip >

_GUIToolTip_GetBubbleSize

Obtient la taille d'une bulle d'un contrôle info-bulle

#include <GuiToolTip.au3>
_GUIToolTip_GetBubbleSize ( $hWnd, $hTool, $iID [, $iFlags = 0x00000001 + 0x00000010] )

Paramètres

$hWnd Handle du contrôle info-bulle (retourné par _GUIToolTip_Create.)
$hTool Handle de la fenêtre qui contient l'élément déclencheur
$iID Handle du contrôle auquel l'élément est associé, ou ID de l'élément
$iFlags [optionnel] Flags qui contrôlent l'affichage de l'info-bulle
    TTF_IDISHWND = Indique que $iID est le handle de la fenêtre de l'élément à la place de l'ID
    TTF_CENTERTIP = Centre la fenêtre au dessous de l'élément spécifié par $iID
    TTF_RTLREADING = Indique que le texte sera affiché dans la direction opposée
    TTF_SUBCLASS = Indique que le contrôle doit prendre le dessus sur la fenêtre de l'élément déclencheur pour intercepter les messages
    TTF_TRACK = Positionne l'info-bulle proche de l'élément déclencheur
    TTF_ABSOLUTE = Positionne la fenêtre aux mêmes coordonnées fournies par TTM_TRACKPOSITION
    TTF_TRANSPARENT = Force le contrôle à transmettre les messages de la souris à la fenêtre parent
    TTF_PARSELINKS = Indique que les liens dans le texte du contrôle doivent être affichés en tant que liens

Les constantes sont définies dans ToolTipConstants.au3

Valeur de retour

Retourne la largeur de l'info-bulle dans le mot de poids faible et la hauteur dans le mot de poids fort.

Remarque

Cette fonction ne fonctionne correctement que sur une info-bulle avec tracking, si le tracking n'a pas été activé pour l'info-bulle vous obtiendrez des valeurs de retour incorrectes.

En relation

_GUIToolTip_GetBubbleHeight, _GUIToolTip_GetBubbleWidth

Exemple

#include <GUIConstantsEx.au3>
#include <GuiToolTip.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIConv.au3>

Example()

Func Example()
    Local $hGUI = GUICreate(StringTrimRight(@ScriptName, StringLen(".exe")), 350, 200)

    Local $idButton = GUICtrlCreateButton("This is a button", 30, 32, 130, 28)
    Local $hButton = GUICtrlGetHandle($idButton)
    ; Crée un contrôle info-bulle avec les paramètres par défaut
    Local $hToolTip = _GUIToolTip_Create(0)
    ; Ajoute un élément au contrôle info-bulle
    _GUIToolTip_AddTool($hToolTip, 0, "This is a ToolTip", $hButton)
    GUISetState(@SW_SHOW)
    _GUIToolTip_TrackActivate($hToolTip, True, 0, $hButton)

    Local $iBubbleHeight = _WinAPI_HiWord(_GUIToolTip_GetBubbleSize($hToolTip, 0, $hButton))
    Local $iBubbleWidth = _WinAPI_LoWord(_GUIToolTip_GetBubbleSize($hToolTip, 0, $hButton))
    ; Affiche la taille de la bulle du tooltip en pixels
    MsgBox($MB_SYSTEMMODAL, "Info", "Bubble Height = " & @TAB & $iBubbleHeight & " Pixels" & @CRLF & _
            "Bubble Width = " & @TAB & $iBubbleWidth & " Pixels")
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Détruit le contrôle info-bulle
    _GUIToolTip_Destroy($hToolTip)
    GUIDelete($hGUI)
EndFunc   ;==>Example