UDF > GUI > GuiToolTip >

_GUIToolTip_TrackActivate

Active ou désactive un contrôle info-bulle qui suit la souris

#include <GuiToolTip.au3>
_GUIToolTip_TrackActivate ( $hWnd [, $bActivate = True [, $hTool = 0 [, $iID = 0]]] )

Paramètres

$hWnd Handle du contrôle info-bulle (retourné par _GUIToolTip_Create.)
$bActivate [optionnel] True pour activer, false pour désactiver
$hTool [optionnel] Handle de la fenêtre qui contient l'élément
$iID [optionnel] Handle du contrôle auquel l'élément est assigné, ou identifiant de l'élément défini par l'application

Valeur de retour

Aucune.

Remarque

Vous devez utiliser cette fonction pour activer une info-bulle qui traque la souris avant de mettre à jour sa position à l'aide de _GUIToolTip_TrackPosition().
Si vous utilisez _GUIToolTip_TrackPosition() sans utiliser _GUIToolTip_TrackActivate() alors l'élément s'affichera uniquement lorsque la souris survolera la fenêtre ou le contrôle assigné, le cas échéant.

En relation

_GUIToolTip_TrackPosition

Exemple

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>

Example()

Func Example()
    Local $hGUI = GUICreate(StringTrimRight(@ScriptName, StringLen(".exe")), 350, 200)

    Local $hToolTip = _GUIToolTip_Create(0, $TTS_BALLOON)
    ; Ajoute au contrôle info-bulle, sans utiliser de contrôle ou de GUI pour l'y associer
    _GUIToolTip_AddTool($hToolTip, 0, " ", 0, 0, 0, 0, 0, $TTF_SUBCLASS)

    _GUIToolTip_SetTitle($hToolTip, 'Mouse position', $TTI_INFO)
    GUISetState(@SW_SHOW)

    _GUIToolTip_TrackActivate($hToolTip, True, 0, 0)
    Local $aPos, $iOldaPos0, $iOldaPos1
    
    Do
        Sleep(10)
        $aPos = MouseGetPos()
        If $aPos[0] <> $iOldaPos0 Or $aPos[1] <> $iOldaPos1 Then
            _GUIToolTip_TrackPosition($hToolTip, $aPos[0] + 10, $aPos[1] + 20)
            _GUIToolTip_UpdateTipText($hToolTip, 0, 0, "X: " & $aPos[0] & " Y: " & $aPos[1])
            $iOldaPos0 = $aPos[0]
            $iOldaPos1 = $aPos[1]  
        EndIf
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    
    ; Détruit le contrôle info-bulle
    _GUIToolTip_Destroy($hToolTip)
    GUIDelete($hGUI)
EndFunc   ;==>Example