Functions > GUI > GUICtrlCreate >

GUICtrlCreateList

Crée un contrôle List pour une GUI.

GUICtrlCreateList ( "text", left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )

Paramètres

text Le texte du contrôle.
left Coordonnée X du coin supérieur gauche du contrôle. Si -1 est utilisé alors X sera déterminée en accord avec GUICoordMode.
top Coordonnée Y du coin supérieur gauche du contrôle. Si -1 est utilisé alors Y sera déterminée en accord avec GUICoordMode.
width [optionnel] Largeur du contrôle (par défaut, la largeur utilisée précédemment).
height [optionnel] Hauteur du contrôle (par défaut, la hauteur utilisée précédemment).
style [optionnel] Définit le style du contrôle. Consultez Annexe des styles des contrôles GUI.
    Par défaut (-1) : $LBS_SORT, $WS_BORDER, $WS_VSCROLL
    Styles forcés : $WS_TABSTOP, $LBS_NOTIFY
exStyle [optionnel] Définit le style étendu du contrôle. Consultez Table des styles étendus.
    Par défaut (-1) : $WS_EX_CLIENTEDGE

Valeur de retour

Succès: Retourne l'ID du nouveau contrôle.
Échec: Retourne 0.

Remarques

Pour obtenir la valeur du contrôle, consultez GUICtrlRead.
Pour régler ou changer l'information dans le contrôle Consultez GUICtrlUpdate....

Les différentes entrées de liste qui peuvent être sélectionnées peuvent être réglées avec GUICtrlSetData

Pour limiter l'utilisation de défilement horizontal GUICtrlSetLimit

Pour combiner les styles avec l'utilisation de style par défaut BitOR($GUI_SS_DEFAULT_LIST, newstyle,...).
Pour utiliser les valeurs spécifiées ci-dessus, vous devez inclure #include <ListBoxConstants.au3> dans votre script.

Le redimensionnement par défaut est $GUI_DOCKAUTO la taille et la position seront modifiées.

En relation

GUICoordMode (Option), GUICtrlSetData, GUICtrlSetLimit, GUICtrlUpdate..., GUIGetMsg

Exemple

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $sMESSAGE = "Les boutons suivants ont été cliqués"

    GUICreate("My GUI list") ; Crée une GUI centrée

    Local $idAdd = GUICtrlCreateButton("Ajoute", 64, 32, 75, 25)
    Local $idClear = GUICtrlCreateButton("Efface", 64, 72, 75, 25)
    Local $idMylist = GUICtrlCreateList("Boutons qui ont été cliqués", 176, 32, 121, 97)
    GUICtrlSetLimit(-1, 200) ; Limite le défilement horizontal
    GUICtrlSetData(-1, $sMESSAGE)
    Local $idClose = GUICtrlCreateButton("Bouton pour arrêter", 64, 160, 175, 25)

    GUISetState(@SW_SHOW)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Local $idMsg = GUIGetMsg()
    While $idMsg <> $GUI_EVENT_CLOSE And $idMsg <> $idClose 
        Switch $idMsg
            Case $idAdd
                GUICtrlSetData($idMylist, "Vous avez cliqué sur le bouton N°1!")
            Case $idClear
                GUICtrlSetData($idMylist, "")
        EndSwitch
        $idMsg = GUIGetMsg()
    WEnd

    If $idMsg = $idClose then
        MsgBox($MB_SYSTEMMODAL, "", "Vous avez cliqué sur le bouton de fermeture", 2)
    EndIf
EndFunc   ;==>Example