UDF > GUI > GuiTab >

_GUICtrlTab_GetItem

Obtient des informations sur un onglet

#include <GuiTab.au3>
_GUICtrlTab_GetItem ( $hWnd, $iIndex )

Paramètres

$hWnd ID/handle du contrôle Tab
$iIndex Index, de base 0, de l'onglet

Valeur de retour

Retourne un tableau avec le format suivant:
    [0] - Flag d'état de l'objet:
        $TCIS_BUTTONPRESSED - L'onglet est sélectionné
        $TCIS_HIGHLIGHTED - L'onglet est en surbrillance
    [1] - Texte de l'onglet
    [2] - Index, de base 0, de l'image de l'onglet ou -1 si l'onglet n'a pas d'image
    [3] - La donnée définie par l'application

En relation

_GUICtrlTab_SetItem

Exemple

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiTab.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $aItem, $idTab, $hImage, $idTab0

    ; Crée une GUI
    GUICreate("Tab Control Get Item", 400, 300)
    $idTab = GUICtrlCreateTab(2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Crée des images
    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
    _GUICtrlTab_SetImageList($idTab, $hImage)

    ; Ajoute des onglets
    $idTab0 = GUICtrlCreateTabItem("Tab 0")
    $g_idMemo = GUICtrlCreateEdit("", 4, 28, 390, 265)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUICtrlCreateTabItem("")
    GUICtrlCreateTabItem("Tab 1")
    GUICtrlCreateTabItem("")
    GUICtrlCreateTabItem("Tab 2")
    GUICtrlCreateTabItem("")
    GUICtrlSetState($idTab0, $GUI_SHOW)

    ; Obtient/Définit tab 0
    _GUICtrlTab_SetItem($idTab, 0, "New Text", BitOR($TCIS_BUTTONPRESSED, $TCIS_BUTTONPRESSED), 2)
    _GUICtrlTab_SetItem($idTab, 1, -1, -1, 4)
    _GUICtrlTab_SetItem($idTab, 2, -1, -1, 5)
    GUISetState(@SW_LOCK)
    For $x = 0 To 2
        $aItem = _GUICtrlTab_GetItem($idTab, $x)
        MemoWrite("Tab Item " & $x & @CRLF & "---------------------")
        For $y = 0 To 3
            MemoWrite("$aItem[" & $y & "]: " & $aItem[$y])
        Next
        MemoWrite(@CRLF & "---------------------")
    Next
    GUISetState(@SW_UNLOCK)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite